Testu-funtzioak

Atal honek Testua funtzioen deskribapenak ditu.

Komando hau erabiltzeko...

Txertatu - Funtzioa - Testua kategoria


Using double quotation marks in formulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

  1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

  2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the Tools - AutoCorrect Options - Localized Options dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the Replace toggle button to disable the feature.

ARABIC

Returns the numeric value corresponding to a Roman number expressed as text.

ASC

Converts double-byte (full-width) characters to single-byte (half-width) ASCII and katakana characters.

JIS

Converts single-byte (half-width) ASCII or katakana characters to double-byte (full-width) characters.

REGEX

Bat etortzeak eta erauzteak egiten ditu, edo aukeran ordezteak egiten ditu, adierazpen erregularrak erabilita.

ROMAN

Converts a number into a Roman numeral. The value range must be between 0 and 3999. A simplification mode can be specified in the range from 0 to 4.

VALUE

Converts the string representation of a number to numeric form. If the supplied string is a valid date, time, or date-time, the corresponding date-time serial number is returned.

WEBSERVICE

Web-edukia URI batetik eskuratzea.

FILTERXML

Aplikatu XPath adierazpen bat XML dokumentu bati.

ENCODEURL

URL kodetuko kate bat itzultzen du.

BAHTTEXT

Zenbaki bat Thailandierazko testura bihurtzen du, thailandiar moneta-izenak barne.

Sintaxia

BAHTTEXT(Zenbakia)

Zenbakia: edozein zenbaki da. "Baht" zenbakiaren osoko zatiari eransten zaio, eta "Satang", berriz, zenbakiaren dezimal zatiari.

Adibidea

=BAHTTEXT(12,65): Thailandierako karaktereekin idatzitako kate bat ematen du, hauxe esan nahi duena: "Hamabi Baht eta hirurogeita bost Satang".

BASE

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

Sintaxia

BASE(Zenbakia; Erroa [; GutxienekoLuzera])

Zenbakia: bihurtu beharreko osoko zenbaki positiboa.

Erroa: zenbaki sistemaren oinarria adierazten du. 2 eta 36 arteko edozein osoko zenbaki positibo izan daiteke.

GutxienekoLuzera (aukerakoa): sortutako karaktere-sekuentziaren gutxieneko luzera zehazten du. Testua ez bada adierazitako gutxieneko luzerara iristen, zeroak gehituko dira karaktere-katearen ezkerraldean.

Adibidea

=BASE(17;10;4): 0017 ematen du sistema hamartarrean.

=BASE(17;2): 10001 ematen du sistema bitarrean.

=BASE(255;16;4): 00FF ematen du sistema hamaseitarrean.

CHAR

Zenbaki bat karaktere bihurtzen du, uneko kode-taularen arabera. Zenbakia bi digituko nahiz hiru digituko osoko zenbakia izan daiteke.

127 kode baino gehiagokoak sistemaren karaktere-mapaketaren araberakoak izango dira (iso-8859-1, iso-8859-2, Windows-1252, Windows-1250 esate baterako), eta beraz baliteke eramangarria ez izatea.

Sintaxia

CHAR(zenbakia)

Zenbakia: karakterearen kode-balioa adierazten duen 1 eta 255 arteko zenbakia.

Adibidea

=CHAR(100): d karakterea ematen du.

="abc" & CHAR(10) & "def" funtzioak lerro-jauziaren karakterea sartzen du katean.

CLEAN

Inprimatzekoak ez diren karaktereak kendu egingo dira katetik.

Sintaxia

CLEAN(testua)

Testua: inprimatzekoak ez diren karaktereak kendu behar zaizkion testua.

Adibidea

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) funtzioak 16 itzultzen du, CLEAN funtzioak inprimagarriak ez diren U+0007 ("BEL") eta U+0008 ("BS") Unicode karaktereak ezabatzen dituela kate-argumentuaren hasieran eta amaieran. CLEAN funtzioak ez ditu zuriuneak kentzen.

CODE

Testu-kate bateko lehen karakterearen zenbakizko kodea ematen du.

Sintaxia

CODE(Testua)

Testua: lehen karakterearen kodea zehaztu behar zaion testua da.

127 kode baino gehiagokoak sistemaren karaktere-mapaketaren araberakoak izango dira (iso-8859-1, iso-8859-2, Windows-1252, Windows-1250 esate baterako), eta beraz baliteke eramangarria ez izatea.

Adibidea

=CODE("Hieronymus") funtzioak 72 ematen du; =CODE("hieroglyphic") funtzioak 104 ematen du.

note

Hemen erabilitako kodea ez da ASCII, unean kargatutako kode-taula baizik.


CONCATENATE

Hainbat testu-kate konbinatzen ditu kate bakar batean.

Sintaxia

CONCATENATE(Katea 1 [; Katea 2 [; … [; Katea 255]]])

1. katea[; 2. katea][; … ;[255. katea]] kateak dira edo kateak dituzten gelaxken erreferentziak dira.

Adibidea

=CONCATENATE("Egun";"on";"Arregi. ";"andrea") funtzioak honako hau ematen du: Egun on Arregi andrea.

DECIMAL

Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

Erroa 16 bada, ezkerrean x edo X edo 0x edo 0X gehituko da, eta erantsitako h edo H ez dira kontuan hartuko. Erroa 2 bada, erantsitako b edo B ez dira kontuan hartuko. Zenbaki-sistemari ez dagozkion bestelako karaktereek errorea emango dute.

Sintaxia

DECIMAL(testua; erroa)

Testua: bihurtu beharreko testua. Zenbaki hamaseitar bat, A1 adibidez, eta A1 gelaxkaren erreferentzia desberdintzeko, zenbakia komatxo artean idatzi behar duzu. Adibidez, "A1" edo "FACE".

Erroa: zenbaki sistemaren oinarria adierazten du. 2 eta 36 arteko edozein osoko zenbaki positibo izan daiteke.

Adibidea

=DECIMAL("17";10): 17 ematen du.

=DECIMAL("FACE";16): 64206 ematen du.

=DECIMAL("0101";2): 5 ematen du.

DOLLAR

Zenbaki bat moneta-formatuko kopuru batera bihurtzen du, zehaztutako dezimal kopuruaren arabera biribilduta. Balioa eremuan, sartu monetara bihurtu beharreko zenbakia. Nahiz izanez gero, dezimal kopurua sar dezakezu Dezimalak eremuan. Ez bada baliorik zehazten, moneta-formatuko zenbaki guztiak bi dezimalekin bistaratuko dira.

Sistemaren ezarpenetan ezartzen da moneta-formatua.

Sintaxia

DOLLAR(Balioa [; Dezimalak])

Balioa: zenbaki bat da, zenbaki bat duen gelaxka baten erreferentzia edo zenbaki bat ematen duen formula.

Dezimalak leku dezimalen aukerako kopurua da.

Adibidea

=DOLLAR(255) funtzioak $255.00 itzultzen du ingeleseko (USA) hizkuntza-ezarpenarekin eta USD (dolar) monetarekin; ¥255.00 itzultzen du japonierako hizkuntza-ezarpenarekin eta JPY (yen) monetarekin; edo 255,00 € alemanierako (Alemania) hizkuntza-ezarpenarekin eta EUR (euro) monetarekin.

=DOLLAR(367,456;2): $367,46 ematen du. Erabili uneko ezarpen lokalari dagokion dezimalen bereizlea.

EXACT

Bi testu-kate konparatzen ditu, eta TRUE ematen du berdinak baldin badira. Funtzio honek maiuskulak eta minuskulak bereizten ditu.

Sintaxia

EXACT(testua_1;testua_2)

Testua1: konparatzeko lehen testua.

Testua2: konparatzeko bigarren testua.

Adibidea

=EXACT("microsystems";"Microsystems") FALSE itzultzen du.

FIND

Testu-kate batek beste kate baten barruan duen kokapena itzultzen du. Bilaketa non hasi ere defini dezakezu. Bilaketa-terminoa zenbaki bat edo edozein karaktere-kate izan daiteke. Bilaketak maiuskulak eta minuskulak bereizten ditu.

Sintaxia

FIND("BilaketaTestua"; "Testua" [; Kokagunea])

BilaketaTestua: bilatu nahi den testua.

Testua: bilaketa zein testutan egingo den zehazten du.

Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.

Adibidea

=FIND(76;998877665544): 6 ematen du.

FIXED

Zenbakia testu gisa itzultzen du dezimalen eta aukerako milako bereizleen kopuru jakin batekin.

Sintaxia

FIXED(Zenbakia; Dezimalak = 2 [; MilakoenBereizlerikEz = FALSE]])

Zenbakia biribildu egingo da Dezimalak tokiekin (dezimalen bereizlearen ondoren) eta emaitzari testuaren formatua emango zaio hizkuntzaren araberako ezarpenak erabilita.

Dezimalak (aukerakoa) parametroak bistaratuko den dezimal kopurua adierazten du. Dezimalak negatiboa bada, Zenbakia biribildu egingo da ABS(Dezimalak) tokietara dezimalen markatik ezkerrera. Dezimalak zatiki bat bada, moztu egingo da eta ez ikusiarena egingo zaio osoko zenbaki hurbilenari.

MilakoenBereizlerikEz (aukerakoa) parametroak milakoen bereizlea erabiliko den ala ez zehazten du. TRUE bada edo zero ez bada, talde-bereizleak ez dira erabiliko emaitza gisa sortuko den katean. Parametroa 0 bada edo ez bada eman, uneko hizkuntza-ezarpenaren milakoen bereizlea erabiliko da.

Adibidea

=FIXED(1234567,89;3) funtzioak 1.234.567,890 itzultzen du testu-kate gisa.

=FIXED(123456.789;;TRUE) funtzioak 123456.79 itzultzen du testu-kate gisa.

=FIXED(12345.6789;-2) funtzioak 12.300 itzultzen du testu-kate gisa.

=FIXED(12134567.89;-3;1) funtzioak 12135000 itzultzen du testu-kate gisa.

=FIXED(12345.789;3/4) funtzioak 12,346 itzultzen du testu-kate gisa.

=FIXED(12345.789;8/5) funtzioak 12.345,8 itzultzen du testu-kate gisa.

LEFT

Testu-kateko lehen karakterea edo karaktereak ematen ditu.

Sintaxia

LEFT("Testua" [; Zenbakia])

Testua: hasierako hitz partzialak zehazteko testua.

Zenbakia (aukerakoa): hasierako testuaren karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibidea

=LEFT("irteera";3): “irt” ematen du.

LEFTB

DBCS testu-kateko lehen karakterea ematen ditu.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

LEFTB("Testua" [; Byte_kopurua])

Testua: hasierako hitz partzialak zehazteko testua.

Byte_kopurua (aukerakoa): LEFTB funtzioak aterako dituen karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibidea

=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

LEN

Kate baten luzera ematen du, zuriuneak barne.

Sintaxia

LEN("testua")

Testua: luzera zehaztu beharreko testua da.

Adibidea

=LEN("Egun zoragarria"): 15 ematen du.

=LEN(12345,67): 8 ematen du.

LENB

Byte bikoitzeko karaktere multzoko (DBCS) hizkuntzetarako, karaktereak testu-kate batean ordezkatzeko erabiltzen den byte kopurua ematen du.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

LENB("Testua")

Testua: luzera zehaztu beharreko testua da.

Adibidea

LENB("中"): 2 ematen du (2 byte dituen DBCS karaktere bat).

LENB("中国"): 4 ematen du (bakoitzak 2 byte dituen 2 DBCS karaktere).

LENB("office"): 6 ematen du (bakoitzak byte 1 duen eta DBCS ez diren 6 karaktere).

=LENB("Egun zoragarria"): 15 ematen du.

=LENB(12345,67): 8 ematen du.

LOWER

Testu-kateko letra maiuskula guztiak minuskula bihurtzen ditu.

Sintaxia

LOWER("testua")

Testua: bihurtu beharreko testua.

Adibidea

=LOWER("Eguzkia"): eguzkia ematen du.

MID

Testu baten testu-katea ematen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.

Sintaxia

MID("testua"; hasiera; kopurua)

Testua: erauzi beharreko karaktereak dituen testua da.

Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokagunea.

Zenbakia (aukerakoa): testu zatiko karaktere kopurua zehazten du.

Adibidea

=MID("office";2;2): ff ematen du.

MIDB

DBCS testu baten testu-katea itzultzen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

MIDB("Testua"; Hasiera; Byte_kopurua)

Testua: erauzi beharreko karaktereak dituen testua da.

Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokagunea.

Byte_kopurua: MIDBk testutik emango duen karaktere kopurua, bytetan, zehazten du.

Adibidea

=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

PROPER

Testu-kate bateko hitz guztietako lehen letra maiuskulaz ipintzen du.

Sintaxia

PROPER("testua")

Testua: bihurtu beharreko testua.

Adibidea

=PROPER("the document foundation") funtzioak 'The Document Foundation' itzultzen du.

REPLACE

Testu-kate baten zati bat ordezten du beste testu-kate batekin. Funtzio hau karaktereak nahiz zenbakiak ordezteko erabil daiteke (zenbakiak normalean testu bihurtzen dira). Funtzioaren emaitza testu gisa bistaratzen da beti. Gero kalkuluak egin nahi badituzu testu bihurtu den zenbaki batekin, berriro zenbaki bihurtu beharko duzu VALUE funtzioarekin.

Zenbakiak dituen edozein testu komatxoen artean idatzi behar da, ez baduzu nahi zenbaki gisa interpretatu eta automatikoki testu bihurtzea.

Sintaxia

REPLACE("Testua"; Kokagunea; Luzera; "TestuBerria")

Testua: zati bat ordeztuko zaion testua.

Kokagunea: testuaren barruan ordezpen-prozesua hasiko den tokia.

Luzera: Testua katean ordeztu beharreko karaktere kopurua.

Testu berria: Testua ordeztuko duen testua.

Adibidea

=REPLACE("1234567";1;1;"444"): "444234567" ematen du. 1 kokaguneko karaktere bat Testu berri osoak ordeztuko du.

REPT

Karaktere-kate bat zehaztutako kopia kopuruarekin errepikatuko du.

Sintaxia

REPT("testua"; kopurua)

Testua: errepikatu beharreko testua.

Kopurua: errepikapenen kopurua.

Adibidea

=REPT("Egun on";2): Egun onEgun on ematen du.

tip

Refer to the REPT wiki page for more details about this function.


RIGHT

Testu baten azkenengo karakterea edo karaktereak itzultzen du.

Sintaxia

RIGHT("Testua" [; Zenbakia])

Testua: eskuineko zatia zehaztu behar zaion testua.

Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.

Adibidea

=RIGHT("Eguzkia";2): ia ematen du.

RIGHTB

Byte bikoitzeko karaktere multzoak (DBCS) dituen testu bateko azken karakterea edo karaktereak ematen ditu.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

RIGHTB("Testua" [; Byte_kopurua])

Testua: eskuineko zatia zehaztu behar zaion testua.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

Adibidea

RIGHTB("中国";1) " " ematen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

RIGHTB("中国";2): "国" ematen du (2 byte-k DBCS karaktere oso bat osatzen dute).

RIGHTB("中国";3): " 国" ematen du (3 byte-k DBCS karaktere baten erdi bat eta DBCS karaktere oso bat osatzen dute; zuriune bat itzultzen da lehen erdirako).

RIGHTB("中国";4): "中国" ematen du (4 byte-k bi DBCS karaktere oso egiten dute).

RIGHTB("office";3): "ice" ematen du (DBCS ez diren 3 karaktere, bakoitza 1 byte-koa).

SEARCH

Testu-segmentu batek karaktere-kate batean duen kokagunea ematen du. Nahi izanez gero, bilaketa non hasiko den zehaztu dezakezu. Bilaketa-testua zenbaki bat edo edozein karaktere-sekuentzia izan daiteke. Bilaketak ez ditu maiuskulak eta minuskulak bereizten. Testua aurkitzen ez bada, 519 errorea (#VALUE) itzultzen du.

Bilaketak komodinak edo adierazpen erregularrak onartzen ditu. Adierazpen erregularrak gaituta badaude, "den.*" sartu daiteke, adibidez, edozein karaktere kopururekin jarraitutako "den" katearen lehen agerraldia bilatzeko. Adierazpen erregularra den testuren bat bilatu nahi bada, karaktere bakoitzari "\" karakterea jarri behar zaio aurretik, edo testua \Q...\E karaktereen artean sartu behar da. Komodinen edo adierazpen erregularren ebaluazio automatikoa aktibatzeko/desaktibatzeko, erabili - LibreOffice Calc - Kalkulatu.

warning

Adierazpen erregular bat ordezkatzen duten bilaketa-irizpideko kateak diren argumentu bat edo gehiago dituzten funtzioak erabiltzean, lehen aldian kate-irizpide horiek zenbaki bihurtzeko saialdia egingo da. Adibidez, ".0" katea 0.0 bihurtuko da, eta abar. Ongi bihurtzen bada, bat etortzea ez da izango adierazpen erregularreko bat etortzea, baizik eta zenbakizko bat etortzea. Hala ere, dezimalen bereizlea puntua ez den hizkuntza batean, adierazpen erregularraren bihurketak funtzionatu egingo du. Zenbakizko adierazpen bat sortu ordez adierazpen erregularraren ebaluazioa behartzeko, erabili zenbakitzat hartu ezin daitezkeen adierazpenak, adibidez ".[0]" edo ".\0" edo "(?i).0".


Sintaxia

SEARCH("BilaketaTestua"; "Testua" [; Kokagunea])

BilaketaTestua: bilatu beharreko testua.

Testua: bilaketa zein testutan egingo den zehazten du.

Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.

Adibidea

=SEARCH(54;998877665544): 10 ematen du.

SUBSTITUTE

Kate bateko testu zaharra testu berriarekin ordezten du.

Sintaxia

SUBSTITUTE("Testua"; "BilaketaTestua"; "TestuBerria" [; Agerraldia])

Testua: testu-segmentuak trukatu behar zaizkion testua.

Bilatutako_testua: (hainbat aldiz) ordeztu beharreko testu-segmentua.

Testu berria: testu-segmentua ordeztuko duen testua.

Agerraldia (aukerakoa): bilatutako testuaren zein agerraldi ordeztu behar den zehazten du. Parametro hau agertzen ez bada, agerraldi guztiak ordeztuko dira.

Adibidea

=SUBSTITUTE("123123123";"3";"abc"): 12abc12abc12abc ematen du.

=SUBSTITUTE("123123123";"3";"abc";2): 12312abc123 ematen du.

T

Funtzio honek helburuko testua itzultzen du, edo testu-kate huts bat, helburua testua ez bada.

Sintaxia

T(balioa)

Balioa testu-kate bat da, edo testu-kate bati egiten dio erreferentzia; T-k testu-atea itzultzen du, edo, bestela, testu-kate huts bat.

Adibidea

=T(12345): kate huts bat ematen du.

=T("12345"): 12345 ematen du.

TEXT

Balio bat testu bihurtzen du emandako formatu baten arabera.

Sintaxia

TEXT(Balioa; Formatua)

Balioa: Bihurtuko den balioa (zenbakizkoa edo testuzkoa) da.

Formatua: formatua definitzen duen testua. Gelaxka-formatuan ezarritako hizkuntzaren araberako dezimal eta milakoen bereizleak erabili.

Adibidea

=TEXT(12,34567;"###.##"): 12,35 testua ematen du

=TEXT(12,34567;"000,00"): 012,35 testua ematen du

=TEXT("xyz";"=== @ ===") funtzioak === xyz === testua itzultzen du

tip

Ikus baita ere Zenbakien formatu-kodeak: erabiltzaileak definitutako formatu-kode pertsonalizatuak.


TRIM

Kate bateko zuriuneak kentzen ditu, zuriune-karaktere bakar bat utziz hitzen artean.

Sintaxia

TRIM("Testua")

Testua zuriuneak kenduko zaizkion testua da.

Adibidea

=TRIM(" kaixo mundua "): 'kaixo mundua' ematen du, aurreko eta atzeko zuriuneak kenduta eta hitzen artean zuriune bakarrak utzita.

UNICHAR

Kode-zenbaki bat Unicode karaktere edota letra bihurtzen du.

Sintaxia

UNICHAR(zenbakia)

Adibidea

=UNICHAR(169): © copyright-karakterea ematen du.

tip

Ikus, baita ere, UNICODE() funtzioa.


UNICODE

Testu-kate bateko lehen Unicode karakterearen zenbakizko kodea ematen du.

Sintaxia

UNICODE("Testua")

Adibidea

=UNICODE("©"): copyright-karakterearen 169 Unicode zenbakia ematen du.

tip

Ikusi, baita ere, UNICHAR() funtzioa.


UPPER

Testua eremuan zehaztutako karaktere-katea maiuskuletara bihurtzen du.

Sintaxia

UPPER(testua)

Testua: maiuskuletara bihurtu nahi dituzun minuskulak.

Adibidea

=UPPER("Egun on"): EGUN ON ematen du.