LibreOffice 7.3 laguntza
Atal honek Testua funtzioen deskribapenak ditu.
To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.
The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).
To place a literal double quotation mark within a string inside a formula, two methods can be used:
Komatxo bikoitzek "ihes egin dezaten", komatxo bikoitz gehigarri bat erabili daiteke. Calc aplikazioak balio literaltzat hartuko du ihes egindako komatxo bikoitza. Adibidez, ="Nire izena ""Jon Etxebarria"" da." formulak Nire izena "Jon Etxebarria" da. katea emango du. Beste adibide sinple bat =UNICODE("""") da: horrek 34 itzuliko du, komatxoaren Unicode karakterearen balio hamartarra (U+0022) alegia — adibide horretan lehen eta laugarren komatxo bikoitzek katearen hasiera eta amaiera adierazten dute, eta bigarren komatxo bikoitza hirugarrenak ihes egin dezan erabili da.
You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.
Kontuan izan Calc aplikazioak autozuzenketarako duen funtzioak komatxo bikoitzak aldatu ditzakeela. Zuzenketa automatikoak ez lituzke aldatu beharko komatxo bikoitzak formula-gelaxka barruan, baina formulak ez diren eta testua duten gelaxkatakoak aldatu ditzake. Adibidez, beste edozein motatako komatxo bikoitz tipografikoz, adibidez ezkerreko komatxo bikoitzaz (U+201C) eta eskuineko komatxo bikoitzaz (U+201D), inguratuta dagoen kate bat kopiatzen bada, eta formula-gelaxka batean kopiatzen bada, errore bat gertatu daiteke. Ireki Komatxo bikoitzak area hasierako eta amaierako komatxo bikoitzak automatikoki zuzentzeko erabiliko diren karaktereak ezartzeko. Kendu marka txandakatze-botoiari eginbide hori desgaitzeko.
elkarrizketa-koadrokoZenbaki bat Thailandierazko testura bihurtzen du, thailandiar moneta-izenak barne.
BAHTTEXT(Zenbakia)
Zenbakia: edozein zenbaki da. "Baht" zenbakiaren osoko zatiari eransten zaio, eta "Satang", berriz, zenbakiaren dezimal zatiari.
=BAHTTEXT(12,65): Thailandierako karaktereekin idatzitako kate bat ematen du, hauxe esan nahi duena: "Hamabi Baht eta hirurogeita bost Satang".
Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.
BASE(Zenbakia; Erroa [; GutxienekoLuzera])
Zenbakia: bihurtu beharreko osoko zenbaki positiboa.
Erroa: zenbaki sistemaren oinarria adierazten du. 2 eta 36 arteko edozein osoko zenbaki positibo izan daiteke.
GutxienekoLuzera (aukerakoa): sortutako karaktere-sekuentziaren gutxieneko luzera zehazten du. Testua ez bada adierazitako gutxieneko luzerara iristen, zeroak gehituko dira karaktere-katearen ezkerraldean.
=BASE(17;10;4): 0017 ematen du sistema hamartarrean.
=BASE(17;2): 10001 ematen du sistema bitarrean.
=BASE(255;16;4): 00FF ematen du sistema hamaseitarrean.
Zenbaki bat karaktere bihurtzen du, uneko kode-taularen arabera. Zenbakia bi digituko nahiz hiru digituko osoko zenbakia izan daiteke.
CHAR(zenbakia)
Zenbakia: karakterearen kode-balioa adierazten duen 1 eta 255 arteko zenbakia.
=CHAR(100): d karakterea ematen du.
="abc" & CHAR(10) & "def" funtzioak lerro-jauziaren karakterea sartzen du katean.
Inprimatzekoak ez diren karaktereak kendu egingo dira katetik.
CLEAN(testua)
Testua: inprimatzekoak ez diren karaktereak kendu behar zaizkion testua.
=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) funtzioak 16 itzultzen du, CLEAN funtzioak inprimagarriak ez diren U+0007 ("BEL") eta U+0008 ("BS") Unicode karaktereak ezabatzen dituela kate-argumentuaren hasieran eta amaieran. CLEAN funtzioak ez ditu zuriuneak kentzen.
Testu-kate bateko lehen karakterearen zenbakizko kodea ematen du.
CODE(Testua)
Testua: lehen karakterearen kodea zehaztu behar zaion testua da.
=CODE("Hieronymus") funtzioak 72 ematen du; =CODE("hieroglyphic") funtzioak 104 ematen du.
Hemen erabilitako kodea ez da ASCII, unean kargatutako kode-taula baizik.
Hainbat testu-kate konbinatzen ditu kate bakar batean.
CONCATENATE(Katea 1 [; Katea 2 [; … [; Katea 255]]])
1. katea[; 2. katea][; … ;[255. katea]] kateak dira edo kateak dituzten gelaxken erreferentziak dira.
=CONCATENATE("Egun";"on";"Arregi. ";"andrea") funtzioak honako hau ematen du: Egun on Arregi andrea.
Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.
Erroa 16 bada, ezkerrean x edo X edo 0x edo 0X gehituko da, eta erantsitako h edo H ez dira kontuan hartuko. Erroa 2 bada, erantsitako b edo B ez dira kontuan hartuko. Zenbaki-sistemari ez dagozkion bestelako karaktereek errorea emango dute.
DECIMAL(testua; erroa)
Testua: bihurtu beharreko testua. Zenbaki hamaseitar bat, A1 adibidez, eta A1 gelaxkaren erreferentzia desberdintzeko, zenbakia komatxo artean idatzi behar duzu. Adibidez, "A1" edo "FACE".
Erroa: zenbaki sistemaren oinarria adierazten du. 2 eta 36 arteko edozein osoko zenbaki positibo izan daiteke.
=DECIMAL("17";10): 17 ematen du.
=DECIMAL("FACE";16): 64206 ematen du.
=DECIMAL("0101";2): 5 ematen du.
Zenbaki bat moneta-formatuko kopuru batera bihurtzen du, zehaztutako dezimal kopuruaren arabera biribilduta. Balioa eremuan, sartu monetara bihurtu beharreko zenbakia. Nahiz izanez gero, dezimal kopurua sar dezakezu Dezimalak eremuan. Ez bada baliorik zehazten, moneta-formatuko zenbaki guztiak bi dezimalekin bistaratuko dira.
Sistemaren ezarpenetan ezartzen da moneta-formatua.
DOLLAR(Balioa [; Dezimalak])
Balioa: zenbaki bat da, zenbaki bat duen gelaxka baten erreferentzia edo zenbaki bat ematen duen formula.
Dezimalak leku dezimalen aukerako kopurua da.
=DOLLAR(255) funtzioak $255.00 itzultzen du ingeleseko (USA) hizkuntza-ezarpenarekin eta USD (dolar) monetarekin; ¥255.00 itzultzen du japonierako hizkuntza-ezarpenarekin eta JPY (yen) monetarekin; edo 255,00 € alemanierako (Alemania) hizkuntza-ezarpenarekin eta EUR (euro) monetarekin.
=DOLLAR(367,456;2): $367,46 ematen du. Erabili uneko ezarpen lokalari dagokion dezimalen bereizlea.
Bi testu-kate konparatzen ditu, eta TRUE ematen du berdinak baldin badira. Funtzio honek maiuskulak eta minuskulak bereizten ditu.
EXACT(testua_1;testua_2)
Testua1: konparatzeko lehen testua.
Testua2: konparatzeko bigarren testua.
=EXACT("microsystems";"Microsystems") FALSE itzultzen du.
Testu-kate batek beste kate baten barruan duen kokapena itzultzen du. Bilaketa non hasi ere defini dezakezu. Bilaketa-terminoa zenbaki bat edo edozein karaktere-kate izan daiteke. Bilaketak maiuskulak eta minuskulak bereizten ditu.
FIND("BilaketaTestua"; "Testua" [; Kokagunea])
BilaketaTestua: bilatu nahi den testua.
Testua: bilaketa zein testutan egingo den zehazten du.
Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.
=FIND(76;998877665544): 6 ematen du.
Zenbakia testu gisa itzultzen du dezimalen eta aukerako milako bereizleen kopuru jakin batekin.
FIXED(Zenbakia; Dezimalak = 2 [; MilakoenBereizlerikEz = FALSE]])
Zenbakia biribildu egingo da Dezimalak tokiekin (dezimalen bereizlearen ondoren) eta emaitzari testuaren formatua emango zaio hizkuntzaren araberako ezarpenak erabilita.
Dezimalak (aukerakoa) parametroak bistaratuko den dezimal kopurua adierazten du. Dezimalak negatiboa bada, Zenbakia biribildu egingo da ABS(Dezimalak) tokietara dezimalen markatik ezkerrera. Dezimalak zatiki bat bada, moztu egingo da eta ez ikusiarena egingo zaio osoko zenbaki hurbilenari.
MilakoenBereizlerikEz (aukerakoa) parametroak milakoen bereizlea erabiliko den ala ez zehazten du. TRUE bada edo zero ez bada, talde-bereizleak ez dira erabiliko emaitza gisa sortuko den katean. Parametroa 0 bada edo ez bada eman, uneko hizkuntza-ezarpenaren milakoen bereizlea erabiliko da.
=FIXED(1234567,89;3) funtzioak 1.234.567,890 itzultzen du testu-kate gisa.
=FIXED(123456.789;;TRUE) funtzioak 123456.79 itzultzen du testu-kate gisa.
=FIXED(12345.6789;-2) funtzioak 12.300 itzultzen du testu-kate gisa.
=FIXED(12134567.89;-3;1) funtzioak 12135000 itzultzen du testu-kate gisa.
=FIXED(12345.789;3/4) funtzioak 12,346 itzultzen du testu-kate gisa.
=FIXED(12345.789;8/5) funtzioak 12.345,8 itzultzen du testu-kate gisa.
Testu-kateko lehen karakterea edo karaktereak ematen ditu.
LEFT("Testua" [; Zenbakia])
Testua: hasierako hitz partzialak zehazteko testua.
Zenbakia (aukerakoa): hasierako testuaren karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.
=LEFT("irteera";3): “irt” ematen du.
DBCS testu-kateko lehen karakterea ematen ditu.
LEFTB("Testua" [; Byte_kopurua])
Testua: hasierako hitz partzialak zehazteko testua.
Byte_kopurua (aukerakoa): LEFTB funtzioak aterako dituen karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.
=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).
=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).
=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).
=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).
=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).
Kate baten luzera ematen du, zuriuneak barne.
LEN("testua")
Testua: luzera zehaztu beharreko testua da.
=LEN("Egun zoragarria"): 15 ematen du.
=LEN(12345,67): 8 ematen du.
Byte bikoitzeko karaktere multzoko (DBCS) hizkuntzetarako, karaktereak testu-kate batean ordezkatzeko erabiltzen den byte kopurua ematen du.
LENB("Testua")
Testua: luzera zehaztu beharreko testua da.
LENB("中"): 2 ematen du (2 byte dituen DBCS karaktere bat).
LENB("中国"): 4 ematen du (bakoitzak 2 byte dituen 2 DBCS karaktere).
LENB("office"): 6 ematen du (bakoitzak byte 1 duen eta DBCS ez diren 6 karaktere).
=LENB("Egun zoragarria"): 15 ematen du.
=LENB(12345,67): 8 ematen du.
Testu-kateko letra maiuskula guztiak minuskula bihurtzen ditu.
LOWER("testua")
Testua: bihurtu beharreko testua.
=LOWER("Eguzkia"): eguzkia ematen du.
Testu baten testu-katea ematen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.
MID("testua"; hasiera; kopurua)
Testua: erauzi beharreko karaktereak dituen testua da.
Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokagunea.
Zenbakia (aukerakoa): testu zatiko karaktere kopurua zehazten du.
=MID("office";2;2): ff ematen du.
DBCS testu baten testu-katea itzultzen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.
MIDB("Testua"; Hasiera; Byte_kopurua)
Testua: erauzi beharreko karaktereak dituen testua da.
Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokagunea.
Byte_kopurua: MIDBk testutik emango duen karaktere kopurua, bytetan, zehazten du.
=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).
=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).
=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).
=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).
=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).
=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).
=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).
=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).
=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).
=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).
=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).
Testu-kate bateko hitz guztietako lehen letra maiuskulaz ipintzen du.
PROPER("testua")
Testua: bihurtu beharreko testua.
=PROPER("the document foundation") funtzioak 'The Document Foundation' itzultzen du.
Testu-kate baten zati bat ordezten du beste testu-kate batekin. Funtzio hau karaktereak nahiz zenbakiak ordezteko erabil daiteke (zenbakiak normalean testu bihurtzen dira). Funtzioaren emaitza testu gisa bistaratzen da beti. Gero kalkuluak egin nahi badituzu testu bihurtu den zenbaki batekin, berriro zenbaki bihurtu beharko duzu VALUE funtzioarekin.
Zenbakiak dituen edozein testu komatxoen artean idatzi behar da, ez baduzu nahi zenbaki gisa interpretatu eta automatikoki testu bihurtzea.
REPLACE("Testua"; Kokagunea; Luzera; "TestuBerria")
Testua: zati bat ordeztuko zaion testua.
Kokagunea: testuaren barruan ordezpen-prozesua hasiko den tokia.
Luzera: Testua katean ordeztu beharreko karaktere kopurua.
Testu berria: Testua ordeztuko duen testua.
=REPLACE("1234567";1;1;"444"): "444234567" ematen du. 1 kokaguneko karaktere bat Testu berri osoak ordeztuko du.
Karaktere-kate bat zehaztutako kopia kopuruarekin errepikatuko du.
REPT("testua"; kopurua)
Testua: errepikatu beharreko testua.
Kopurua: errepikapenen kopurua.
=REPT("Egun on";2): Egun onEgun on ematen du.
Refer to the REPT wiki page for more details about this function.
Testu baten azkenengo karakterea edo karaktereak itzultzen du.
RIGHT("Testua" [; Zenbakia])
Testua: eskuineko zatia zehaztu behar zaion testua.
Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.
=RIGHT("Eguzkia";2): ia ematen du.
Byte bikoitzeko karaktere multzoak (DBCS) dituen testu bateko azken karakterea edo karaktereak ematen ditu.
RIGHTB("Testua" [; Byte_kopurua])
Testua: eskuineko zatia zehaztu behar zaion testua.
Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.
RIGHTB("中国";1) " " ematen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).
RIGHTB("中国";2): "国" ematen du (2 byte-k DBCS karaktere oso bat osatzen dute).
RIGHTB("中国";3): " 国" ematen du (3 byte-k DBCS karaktere baten erdi bat eta DBCS karaktere oso bat osatzen dute; zuriune bat itzultzen da lehen erdirako).
RIGHTB("中国";4): "中国" ematen du (4 byte-k bi DBCS karaktere oso egiten dute).
RIGHTB("office";3): "ice" ematen du (DBCS ez diren 3 karaktere, bakoitza 1 byte-koa).
Testu-segmentu batek karaktere-kate batean duen kokagunea ematen du. Nahi izanez gero, bilaketa non hasiko den zehaztu dezakezu. Bilaketa-testua zenbaki bat edo edozein karaktere-sekuentzia izan daiteke. Bilaketak ez ditu maiuskulak eta minuskulak bereizten. Testua aurkitzen ez bada, 519 errorea (#VALUE) itzultzen du.
SEARCH("BilaketaTestua"; "Testua" [; Kokagunea])
BilaketaTestua: bilatu beharreko testua.
Testua: bilaketa zein testutan egingo den zehazten du.
Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.
=SEARCH(54;998877665544): 10 ematen du.
Kate bateko testu zaharra testu berriarekin ordezten du.
SUBSTITUTE("Testua"; "BilaketaTestua"; "TestuBerria" [; Agerraldia])
Testua: testu-segmentuak trukatu behar zaizkion testua.
Bilatutako_testua: (hainbat aldiz) ordeztu beharreko testu-segmentua.
Testu berria: testu-segmentua ordeztuko duen testua.
Agerraldia (aukerakoa): bilatutako testuaren zein agerraldi ordeztu behar den zehazten du. Parametro hau agertzen ez bada, agerraldi guztiak ordeztuko dira.
=SUBSTITUTE("123123123";"3";"abc"): 12abc12abc12abc ematen du.
=SUBSTITUTE("123123123";"3";"abc";2): 12312abc123 ematen du.
Funtzio honek helburuko testua itzultzen du, edo testu-kate huts bat, helburua testua ez bada.
T(balioa)
Balioa testu-kate bat da, edo testu-kate bati egiten dio erreferentzia; T-k testu-atea itzultzen du, edo, bestela, testu-kate huts bat.
=T(12345): kate huts bat ematen du.
=T("12345"): 12345 ematen du.
Balio bat testu bihurtzen du emandako formatu baten arabera.
TEXT(Balioa; Formatua)
Balioa: Bihurtuko den balioa (zenbakizkoa edo testuzkoa) da.
Formatua: formatua definitzen duen testua. Gelaxka-formatuan ezarritako hizkuntzaren araberako dezimal eta milakoen bereizleak erabili.
=TEXT(12,34567;"###.##"): 12,35 testua ematen du
=TEXT(12,34567;"000,00"): 012,35 testua ematen du
=TEXT("xyz";"=== @ ===") funtzioak === xyz === testua itzultzen du
Ikus baita ere Zenbakien formatu-kodeak: erabiltzaileak definitutako formatu-kode pertsonalizatuak.
Kate bateko zuriuneak kentzen ditu, zuriune-karaktere bakar bat utziz hitzen artean.
TRIM("Testua")
Testua zuriuneak kenduko zaizkion testua da.
=TRIM(" kaixo mundua "): 'kaixo mundua' ematen du, aurreko eta atzeko zuriuneak kenduta eta hitzen artean zuriune bakarrak utzita.
Kode-zenbaki bat Unicode karaktere edota letra bihurtzen du.
UNICHAR(zenbakia)
=UNICHAR(169): © copyright-karakterea ematen du.
Ikus, baita ere, UNICODE() funtzioa.
Testu-kate bateko lehen Unicode karakterearen zenbakizko kodea ematen du.
UNICODE("Testua")
=UNICODE("©"): copyright-karakterearen 169 Unicode zenbakia ematen du.
Ikusi, baita ere, UNICHAR() funtzioa.
Testua eremuan zehaztutako karaktere-katea maiuskuletara bihurtzen du.
UPPER(testua)
Testua: maiuskuletara bihurtu nahi dituzun minuskulak.
=UPPER("Egun on"): EGUN ON ematen du.