Tekstfunktioner

Denne sektion indeholder beskrivelser af Tekst-funktionerne.

For at tilgå denne kommando...

Indsæt - Funktion - Kategori Tekst


Using double quotation marks in formulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

  1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

  2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the Tools - AutoCorrect Options - Localized Options dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the Replace toggle button to disable the feature.

ARABIC

Returns the numeric value corresponding to a Roman number expressed as text.

ASC

Converts double-byte (full-width) characters to single-byte (half-width) ASCII and katakana characters.

JIS

Converts single-byte (half-width) ASCII or katakana characters to double-byte (full-width) characters.

REGEX-funktion

Matcher og udtrækker eller erstatter efter tilvalg tekst med regulære udtryk.

ROMAN

Converts a number into a Roman numeral. The value range must be between 0 and 3999. A simplification mode can be specified in the range from 0 to 4.

VALUE

Converts the string representation of a number to numeric form. If the supplied string is a valid date, time, or date-time, the corresponding date-time serial number is returned.

WEBSERVICE

Hent web-indhold fra en URI.

FILTERXML

Tilknytter et XPath-udtryk til et XML-dokument.

ENCODEURL

Returnerer en URL-kodet streng.

BAHTTEKST

Konverterer et tal til Thaitekst, inklusive Thaivalutanavne.

Syntaks

BAHTTEKST(Tal)

Tal er vilkårligt tal. "Baht" bliver føjet til den hele del af tallet, og "Satang" bliver føjet til decimaldelen af tallet.

Eksempel

=BAHTTEKST(12,65) returnerer en streng i Thaitegn med betydningen "Tolv Baht og femogtres Satang".

BASIS (BASE på engelsk)

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

Syntaks

BASIS(Tal; Grundtal [; Minimumslængde])

Tal er det positive heltal, der skal konverteres.

Grundtal indikerer talsystemets basis. Det kan være et vilkårligt positivt heltal mellem 2 og 36.

Minimumslængde (valgfri) bestemmer minimumslængden af tegnsekvensen, der er blevet oprettet. Hvis teksten er kortere end den indikerede minimumslængde, bliver nuller tilføjet til venstre for strengen.

Eksempel

=BASIS(17; 10; 4) returnerer 0017 i det decimale talsystem (titalssystemet).

=BASIS(17; 2) returnerer 10001 i det binære talsystem.

=BASIS(255; 16; 4) returnerer 00FF i det heksadecimale talsystem.

DECIMAL

Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

Hvis det angivne grundtal er 16, ses der bort fra et indledende X, x, 0x eller 0X, og et h eller H i slutningen. Hvis grundtal er 2, ses der bort fra et tilføjet B eller b. Andre tegn, som ikke hører til talsystemet, genererer en fejl.

Syntaks

DECIMAL("Tekst"; Grundtal)

Tekst er den tekst, der skal konverteres. For at skelne mellem et hexadecimalt tal, såsom A1, og referencen til celle A1, skal du placere tallet i anførselstegn, for eksempel "A1" eller "FACE".

Grundtal indikerer talsystemets basis. Det kan være et vilkårligt positivt heltal mellem 2 og 36.

Eksempel

=DECIMAL("17"; 10) returnerer 17.

=DECIMAL("FACE"; 16) returnerer 64206.

=DECIMAL("0101"; 2) returnerer 5.

EKSAKT (EXACT på engelsk)

Sammenligner to tekststrenge og returnerer SAND hvis de er identiske. Denne funktion skelner mellem store og små bogstaver.

Syntaks

EKSAKT("Tekst1"; "Tekst2")

Tekst1 refererer til den første tekst, der skal sammenlignes.

Tekst2 refererer til den anden tekst, der skal sammenlignes.

Eksempel

=EKSAKT("microsystems"; "Microsystems") returnerer FALSK.

ERSTAT (REPLACE på engelsk)

Erstatter en del af en tekststreng med en anden tekststreng. Denne funktion kan bruges til at erstatte både tegn og tal (som automatisk bliver konverteret til tekst). Resultatet for funktionen er altid vist som tekst. Hvis du tilsigter at udføre videre beregninger med tal som er blevet erstattet af tekst, skal du konvertere den tilbage til et tal ved hjælp af VÆRDI funktionen.

Hvilken som helst tekst som indeholder tal skal være omgivet af anførselstegn hvis du ikke ønsker det skal fortolkes som et tal men automatisk betragtes som tekst.

Syntaks

ERSTAT("Tekst"; Placering; Længde; "NyTekst")

Tekst henviser til den tekst hvoraf en del skal erstattes.

Placering henviser til placeringen indeni teksten hvor erstatningen vil begynde.

Længde er antal tegn i Tekst som skal erstattes.

NyTekst refererer til teksten som erstatter Tekst.

Eksempel

ERSTAT("1234567"; 1; 1; "444") returnerer "444234567". Et tegn på placeringen 1 er erstattet af den fuldstændige NyTekst

FAST (FIXED på engelsk)

Returnerer et som tekst med et angivet antal decimalpladser og valgfrie tusindtalskilletegn

Syntaks

FAST(Tal; [Decimaler = 2 [; NoThousandsSeparators = FALSE (Ingen Tusindtalssskilletegn = falsk )]])

Talafrundes til Decimal-pladser (efter decimalskilletegnet) og resultatet formateret som tekst, med lokationspecifikke indstillinger.

Decimals (decimaler) (valgfrie) henviser til antallet af decimalpladser, der skal vises. Hvis Decimals er negative, afrundes Number (tallet) til ABS(Decimals) (absolute decimaler) til venstre for decimaltegnet. Hvis Decimals er en brøk, afkortes og ignorerer faktisk, hvad der er den nærmeste heltal.

NoThousandsSeparators (Ingen tusindtalsskilletegn) (valgfri) bestemmer, om der skal bruges tusindtalsskilletegn. Hvis det er TRUE (sandt) eller ikke-nul, udelades gruppe-skilletegnene fra den resulterende streng. Hvis parameteren er lig med 0 eller hvis den mangler helt, vises tusindtalsskilletegnene i din aktuelle lokaliserings indstillinger.

Eksempel

=FAST(1234567,89;3) returnerer 1.234.567,890 som et tekststreng.

=FAST(123456,789;;TRUE) returnerer 123456,79 som en tekststreng.

=FAST(12345,6789;-2) returnerer 12,300 som en tekststreng.

=FAST(12134567,89;-3;1) returnerer 12135000som en tekststreng.

=FAST(12345,789;3/4) returnerer 12.346 som en tekststreng.

=FAST(12345.789;8/5) returnerer 12.345,8 som en tekststreng.

FIND

Returnerer positionen på en tekststreng i en anden streng. Du kan også definere hvor søgningen skal begynde. Søgeordet kan være et tal eller en vilkårlig streng af tegn. Søgningen skelner mellem store og små bogstaver.

Syntaks

FIND("Find tekst"; "Tekst" [; Position])

FindTekst refererer til teksten, der skal findes.

Tekst er teksten, hvori søgningen finder sted.

Placering (valgfri) er positionen i teksten hvorfra søgningen starter.

Eksempel

=FIND(76; 998877665544) returnerer 6.

GENTAG (REPT på engelsk)

Gentager en tekststreng i et givet antal kopier.

Syntaks

GENTAG("Tekst"; Antal)

Tekst er den tekst, der skal gentages.

Antal er antallet af gentagelser.

Eksempel

=GENTAG("God morgen";2) returnerer God morgenGod morgen.

tip

Refer to the REPT wiki page for more details about this function.


HØJRE (RIGHT på engelsk)

Returnerer tegnene længst til højre i en tekst.

Syntaks

HØJRE( "Tekst" [; Antal])

Tekst er teksten hvor den højre del skal findes.

Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.

Eksempel

=HØJRE("Sun"; 2) returnerer un.

HØJREB

Returnerer det/de sidste tegn i en tekst med double bytes characters sets (DBCS).

tip

Denne funktion er tilgængelig siden LibreOffice 4.2.


Syntaks

HØJREB("Tekst" [; Antal_bytes])

Tekst er den tekst hvoraf den højre del skal bestemmes.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

Eksempel

HØJREB("中国";1) returnerer " " (1 byte er kun et halvt DBCS tegn og derfor returneres et blanktegn).

HØJREB("中国";2) returnerer "国" (2 bytes udgør et helt DBCS tegn).

HØJREB("中国";3) returnerer " 国" (3 bytes udgør ½ DBCS tegn og et helt DBCS tegn; et blanktegn returneres for det første halve tegn).

HØJREB("中国";4) returnerer "中国" (4 bytes udgør to fulde DBCS tegn).

HØJREB("office";3) returnerer "ice" (3 ikke-DBCS tegn hver bestående af 1 byte).

KODE (CODE på engelsk)

Returnerer en numerisk kode for det første tegn i en tekst.

Syntaks

KODE("Tekst")

Tekst er teksten for hvilken koden for det første tegn skal findes.

Koder større end 127 kan afhænge af dit systems tegnsæt (for eksempel iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) og som følge der af ikke være kompatibel.

Eksempel

=KODE("Hieronymus") returnerer 72, =KODE("hieroglyfisk") returnerer 104.

note

Koden, der bruges her, refererer ikke til ASCII, men til den aktuelt indlæste kodetabel.


KR (DOLLAR på engelsk)

Konverterer et tal til et beløb i valutaformatet, afrundet til et angivet antal decimaler. I Værdi-feltet indtastes det tal, der skal konverteres til valuta. Desuden kan du indtaste antal decimaler i feltet Decimaler. Hvis ingen værdi er specificeret, vises alle tal i valutaformat med to decimaler.

Valutaformatet indstiller du i dine systemindstillinger.

Syntaks

KR(Værdi [; Decimaler])

Værdi er et tal, en reference til en celle med et tal, eller en formel, som returnerer et tal.

Decimaler er antallet af decimaler.

Eksempel

=KR(255) returnerer $255.00 for den engelske lokalisering (USA) og valutaen USD (dollar); ¥255.00 for den japanske lokalisering og valutaen JPY (yen); eller 255,00 € for den tyske lokalisering (Tyskland) og valutaen EUR (euro).

KR(367,456; 2) returnerer kr. 367,46. Brug det decimaltegn som svarer til den aktuelle lokalitetsindstilling.

LÆNGDE (LEN på engelsk)

Returnerer længden af en streng inklusiv mellemrum.

Syntaks

LÆNGDE("Tekst")

Tekst er teksten hvis længde skal findes.

Eksempel

=LÆNGDE("God eftermiddag") returnerer 15.

=LÆNGDE(12345,67) returnerer 8.

LÆNGDEB

For sprog med dobbeltbyte-tegnsæt (DBCS) returnerer denne funktion antallet af bytes, som benyttes til at repræsentere tegnene i en tekststreng.

tip

Denne funktion er tilgængelig siden LibreOffice 4.2.


Syntaks

LÆNGDEB("Tekst")

Tekst er teksten hvis længde skal findes.

Eksempel

LÆNGDEB("中") returnerer 2 (et DBCS tegn består af 2 bytes).

LÆNGDEB("中国") returnerer 4 (to DBCS tegn hver på 2 bytes).

LÆNGDEB("office") returnerer 6 (seks ikke-DBCS tegn hver på 1 byte).

=LÆNGDEB("God eftermiddag") returnerer 15.

=LÆNGDEB(12345,67) returnerer 8.

MIDT

Returnerer en del af en tekststreng. Parametrene angiver startpositionen og antal tegn.

Syntaks

MIDT("Tekst"; StartVed; Antal)

Tekst er den tekst som indeholder tegnene der skal findes.

StartVed er placeringen af det første tegn i kildeteksten der skal findes.

Antal angiver antal tegn der skal findes i teksten.

Eksempel

=MIDT("office";2;2) returnerer ff.

MIDTB

Returnerer en tekststreng fra en DBCS-tekst (tekst med dobbeltbyte-tegnsæt). Parametrene angiver startpositionen og antallet af tegn.

tip

Denne funktion er tilgængelig siden LibreOffice 4.2.


Syntaks

MIDB("Tekst"; StartVed; Antal_bytes)

Tekst er den tekst som indeholder tegnene der skal findes.

Start er positionen for det første tegn i den tekst du vil uddrage.

Antal_bytes angiver det antal tegn MIDB vil returnere fra tekst, i bytes.

Eksempel

=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

=MIDB("中国";1;2) returne "中" (2 bytes udgør et fuldstændigt DBCS-tegn).

=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

RENS (CLEAN på engelsk)

Alle kontroltegn fjernes fra strengen.

Syntaks

RENS("Tekst")

Tekst refererer til teksten, hvorfra alle tegn der ikke kan udskrives fjernes.

Eksempel

=LÆNGDE(RENS(TEGN(7) & "LibreOffice Calc" & TEGN(8))) returnerer 16 og viser, at funktionen RENS fjerner de ikke-udskrivelige tegn Unicode U+0007 ("BEL") og U+0008 ("BS") i begyndelsen og slutningen af streng-argumentet. RENS fjerner ikke mellemrum.

SAMMENKÆDNING (CONCATENATE på engelsk)

Kombinerer flere tekststrenge til i én streng.

Syntaks

SAMMENKÆDNING(Streng 1 [; Streng 2 [; … [; Streng 255]]])

Streng 1[; Streng 2][; … ;[Streng 255]] er strenge eller referencer til celler, der indeholder strenge.

Eksempel

=SAMMENKÆDNING("Godmorgen "; "Fr. "; "Jensen") returnerer: Godmorgen Fr. Jensen.

SMÅ.BOGSTAVER (LOWER på engelsk)

Konverterer alle store bogstaver i en tekststreng til små bogstaver.

Syntaks

SMÅ.BOGSTAVER("Tekst")

Tekst refererer til den tekst, der skal konverteres.

Eksempel

=SMÅ.BOGSTAVER("Sol") returnerer sol.

STORE.BOGSTAVER (UPPER på engelsk)

Konverterer strengen angivet i feltet Tekst til store bogstaver.

Syntaks

STORE.BOGSTAVER("Tekst")

Tekst henviser til den tekst med små bogstaver du vil konvertere til store bogstaver.

Eksempel

=STORE.BOGSTAVER("God morgen") returnerer GOD MORGEN.

STORT.FORBOGSTAV (PROPER på engelsk)

Konverterer første bogstav i alle ord til stort bogstav i en tekststreng.

Syntaks

STORT.FORBOGSTAV("Tekst")

Tekst refererer til den tekst, der skal konverteres.

Eksempel

=STORT.FORBOGSTAV("the document foundation") returnerer The Document Foundation.

SØG (SEARCH på engelsk)

Returnerer placeringen af et tekstsegment indenfor en tekststreng. Du kan sætte starten på søgningen som en mulighed. Søgeteksten kan være et tal eller en sekvens af tegn. Søgningen gør ikke forskel på store og små bogstaver. Hvis teksten ikke bliver fundet, returneres fejl 519 (#VALUE).

Søgningen understøtter jokere eller regulære udtryk . Når regulære udtryk er aktiveret, kan du indtaste "al.*", for eksempel for at finde det første sted, hvor "al" følges af vilkårlige tegn. Hvis du vil søge efter en tekst, som også er et regulært udtryk, kan du enten sætte et "\" foran hvert tegn, eller lukke teksten inde i \Q…\E. du kan også slå den automatiske evaluering af jokere eller regulære udtryk til og res i ▸ LibreOffice Calc ▸ Beregn.

warning

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konveretres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til lokalisering, hvor decimaltegnet ikke er punktum, kommer konverteringen fungere. For at gennemtvingen evalueringen af det regulære udtryk frem for et numerisk udtryk bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".


Syntaks

SØG( "Find_tekst"; "Tekst" [; Position])

FindTekst er den tekst, der skal søges efter.

Tekst er teksten der skal søges i.

Placering (valgfri) er den placering i teksten hvor søgningen skal starte.

Eksempel

=SØG(54; 998877665544) returnerer 10.

T

Denne funktion returnerer målteksten eller en tom tekststreng, hvis målet ikke er en tekst.

Syntaks

T(Værdi)

Hvis Værdi er en tekststreng eller refererer til en tekststreng, returnerer T denne tekststreng; ellers returnerer den en tom tekststreng.

Eksempel

=T(12345) returnerer en tom streng "".

=T("12345") returnerer strengen 12345.

TEGN (CHAR på engelsk)

Konverterer et tal til et tegn ifølge den aktuelle kodetabel. Tallet kan være et to- eller trecifret heltal.

Koder større end 127 kan afhænge af dit systems tegnsæt (for eksempel iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) og som følge der af ikke være kompatibel.

Syntaks

TEGN(Tal)

Tal er et heltal mellem 1 og 255, som repræsenterer tegnets talværdi.

Eksempel

TEGN(100) returnerer tegnet d.

="abc" & TEGN(10) & "def" indsætter et linjeskiftskontroltegn ind i strengen.

TEKST (TEXT på engelsk)

Konverterer en værdi til tekst i overensstemmelse med et givet format.

Syntaks

TEKST(Værdi; Format)

Værdi er den værdi (numerisk eller tekstlig), der skal konverteres.

Format er teksten som angiver formatet. Brug decimal og tusindtalsskilletegn ifølge sprogindstillingen i cellens formater.

Eksempel

=TEKST(12,34567;"###,##") returnerer teksten 12,35

=TEKST(12,34567;"000,00")returnerer teksten 012,35

=TEKST("xyz";"=== @ ===") returnerer teksten === xyz ===

tip

Se også Nummerformat koder: tilpassede formatkoder defineret af brugeren.


TRIM

Fjerner mellemrum fra en streng og efterlader kun et enkelt mellemrumstegn mellem ord.

Syntaks

TRIM("Tekst")

Tekst henviser til teksten hvor mellemrum vil blive fjernet.

Eksempel

=TRIM(" hej verden ") returnerer hej verden uden indledende og efterfølgende mellemrum, og med et enkelt mellemrum mellem ordene.

UDSKIFT (SUBSTITUTE på engelsk)

Udskifter delord i en tekst.

Syntaks

UDSKIFT( "Tekst"; "Søgetekst"; "Ny tekst" [; Forekomst])

Tekst er teksten hvor tekstsegmentet skal udskiftes.

SøgTekst er tekstsegmentet som skal erstattes (et antal gange).

NyTekst er teksten som skal erstatte tekstsegmentet.

Forekomst (valgfri) angiver hvilken forekomst af søgeteksten, der skal erstattes. Hvis denne parameter mangler, erstattes alle forekomster.

Eksempel

=UDSKIFT("123123123";"3";"abc") returnerer 12abc12abc12abc

=UDSKIFT("123123123";"3";"abc";2) returnerer 12312abc123

UNICHAR

Konverterer et kodetal til et Unicode-tegn eller -bogstav.

Syntaks

UNICHAR(nummer)

Eksempel

=UNICHAR(169) returnerer copyrighttegnet ©.

tip

Se også UNICODE() funktionen.


UNICODE

Returnerer den numeriske kode for det første Unicodetegn i en tekststreng.

Syntaks

UNICODE("Tekst")

Eksempel

=UNICODE("©") returnerer unicodeværdien 169 for copyrighttegnet.

tip

Se også UNICHAR() funktionen.


VENSTRE (LEFT på engelsk)

Returnerer det eller de første tegn i en tekststreng.

Syntaks

VENSTRE("Tekst" [; Tal])

Tekst er teksten, hvor de første tegn skal findes.

Antal (valgfri) specificerer antal tegn i begyndelsen af teksten. Hvis denne parameter ikke er angivet, returneres ét tegn.

Eksempel

=VENSTRE("resultat"; 3) returnerer "res".

VENSTREB

Returnerer de første tegn af en DBCS-tekst.

tip

Denne funktion er tilgængelig siden LibreOffice 4.2.


Syntaks

VENSTREB("Tekst" [; Antal_bytes])

Tekst er teksten, hvorfra de første tegn skal findes.

Antal_bytes (valgfri) angiver det antal tegn, som du ønsker LEFTB skal udtage, baseret på bytes. Hvis denne parameter ikke er defineret, returneres et enkelt tegn.

Eksempel

=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).