Guida di LibreOffice 7.3
In questa sezione sono descritte le funzioni della categoria Testo.
To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.
The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).
To place a literal double quotation mark within a string inside a formula, two methods can be used:
You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.
You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.
Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the toggle button to disable the feature.
Rimuove gli spazi da una stringa, lasciando un singolo spazio tra le parole.
ANNULLA.SPAZI("Testo")
Testo indica il testo in cui gli spazi devono essere rimossi.
=ANNULLA.SPAZI(" ciao mondo ") restituisce ciao mondo senza spazi davanti e dietro e con un singolo spazio tra le parole.
Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.
BASE(Numero; Radice [; Lunghezza_minima])
Numero è l'intero positivo da convertire.
Radice indica la base del sistema numerico. Può essere un numero intero tra 2 e 36.
Lunghezza minima (opzionale) determina la lunghezza minima della sequenza di caratteri creata. Indicando questo parametro, se il testo è più breve verrà completato con degli zeri a sinistra della stringa.
=BASE(17;10;4) restituisce 0017 nel sistema decimale.
=BASE(17;2) restituisce 10001 nel sistema binario.
=BASE(255;16;4) restituisce 00FF nel sistema esadecimale.
Converte un numero di codice in un carattere o una lettera Unicode.
CARATT.UNI(Numero)
=CARATT.UNI(169) restituisce il carattere di copyright ©.
Vedere anche la funzione UNICODE().
Restituisce il codice numerico del primo carattere di un testo o di una stringa.
CODICE("Testo")
Testo è il testo per il quale si desidera trovare il codice del primo carattere.
La funzione =CODICE("Geronimo") restituisce 71, la funzione =CODICE("geroglifico") 103.
Il codice qui utilizzato non è un codice ASCII ma il codice della tabella corrente.
Converte un numero in un carattere in base alla tabella codici attuale. Il numero può essere un numero intero di due o tre cifre.
CODICE.CARATT(Numero)
Numero è un numero tra 1 e 255 che rappresenta il codice per il carattere.
=CODICE.CARATT(100) restituisce il carattere "d".
="abc" & CODICE.CARATT(10) & "def" inserisce un carattere di nuova riga all'interno della stringa.
Combina più stringhe di testo in un'unica stringa.
CONCATENA(Stringa 1 [; Stringa 2 [; … [; Stringa 255]]])
Stringa 1[; Stringa 2][; … ;[Stringa 255]] sono stringhe o riferimenti a celle contenenti stringhe.
=CONCATENA("Buon";"giorno ";"signora "; "Rossi") restituisce Buongiorno signora Rossi.
Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.
Se la radice è 16, il sistema ignora un eventuale carattere x, X, 0x o 0X iniziale, e i caratteri h o H finali. Se la radice è 2, il sistema ignora un eventuale carattere b o B finale. Altri caratteri non appartenenti al sistema numerico generano un errore.
DECIMALE("Testo"; Radice)
Testo è il testo da convertire. Per differenziarlo da un numero esadecimale, tipo A1 e il riferimento alla cella A1, dovete inserire il numero tra virgolette, per esempio, "A1" o "CADE".
Radice indica la base del sistema numerico. Può essere un numero intero tra 2 e 36.
=DECIMALE("17";10) restituisce 17.
=DECIMALE("CADE";16) restituisce 51934.
=DECIMALE("0101"; 2) restituisce 5.
Restituisce l'ultimo o gli ultimi caratteri di una stringa di testo.
DESTRA("Testo" [; Numero])
Testo è il testo la cui parte destra deve essere determinata.
Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.
=DESTRA("Sole";2) restituisce le.
Restituisce l'ultimo o gli ultimi caratteri di un testo, con gruppi di caratteri a doppio byte (DBCS).
DESTRA.B("Testo" [; Numero_byte])
Testo è il testo la cui parte destra deve essere determinata.
Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.
DESTRA.B("中国";1) restituisce " " (un byte è solo metà carattere DBCS, e viene invece restituito un carattere di spazio).
DESTRA.B("中国";2) restituisce "国" (due byte costituiscono un carattere DBCS completo).
DESTRA.B("中国";3) restituisce " 国" (tre byte costituiscono mezzo carattere DBCS e un carattere DBCS intero; viene restituito uno spazio per il primo mezzo carattere).
DESTRA.B("中国";4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).
DESTRA.B("office";3) restituisce "ice" (tre caratteri non DBCS, ciascuno formato da un byte).
Restituisce un numero come testo con un numero di posizioni decimali fisso e con o senza separatore delle migliaia.
FISSO(Numero; [Decimali = 2 [; Nessun separatore migliaia = FALSO]])
Numero è arrotondato alle posizioni decimali (dopo il separatore decimale) e il risultato formattato come testo, utilizzando le impostazioni locali specifiche.
Decimali (opzionale) si riferisce al numero di posizioni decimali da visualizzare. Se Decimali è negativo, Numero è arrotondato a ASS(Decimali) posizioni alla sinistra della virgola. Se Decimali è una frazione, viene troncato ignorando quale sia l'intero più vicino.
Nessun separatore migliaia (opzionale) determina se debba essere usato il separatore delle migliaia. Se è VERO o diverso da zero, allora i separatori di gruppo vengono omessi dalla stringa risultante. Se il parametro è uguale a 0 o totalmente mancante, vengono visualizzati i separatori delle migliaia delle vostre impostazioni locali attuali.
=FISSO(1234567,89;3) restituisce 1.234.567,890 come stringa di testo.
=FISSO(123456,789;;VERO) restituisce 123456,79 come stringa di testo.
=FISSO(12345,6789;-2) restituisce 12.300 come stringa di testo.
=FISSO(12134567,89;-3;1) restituisce 12135000 come stringa di testo.
=FISSO(12345,789;3/4) restituisce 12.346 come stringa di testo.
=FSSO(12345,789;8/5) restituisce 12.345,8 come stringa di testo.
Confronta due stringhe e restituisce VERO se sono identiche. Questa funzione distingue tra maiuscole e minuscole.
IDENTICO("Testo 1"; "Testo 2")
Testo 1 è il primo testo da confrontare.
Testo 2 è il secondo testo da confrontare.
=IDENTICO("microsystems";"Microsystems") restituisce FALSE.
Rimuove dal testo tutti i caratteri non stampabili.
LIBERA("Testo")
Testo si riferisce al testo da cui rimuovere tutti i caratteri non stampabili.
=LUNGHEZZA(LIBERA(CARATT.UNI(7) & "LibreOffice Calc" & CARATT.UNI(8))) restituisce 16, poiché la funzione LIBERA rimuove tutti i caratteri non stampabili come gli Unicode U+0007 ("BEL") e U+0008 ("BS") all'inizio e alla fine dell'argomento della stringa. LIBERA non rimuove gli spazi.
Per le lingue con gruppo di caratteri a doppio byte (DBCS), restituisce il numero di byte utilizzato per rappresentare i caratteri in una stringa di testo.
LUNGH.B("Testo")
Testo è il testo la cui lunghezza deve essere determinata.
LUNGH.B("中") restituisce 2 (un carattere DBCS formato da due byte).
LUNGH.B("中国") restituisce 4 (due caratteri DBCS, ciascuno formato da due byte).
LUNGH.B("office") restituisce 6 (sei caratteri non DBCS, ciascuno formato da un byte).
=LUNGH.B("Buongiorno") restituisce 14.
=LUNGH.B(12345,67) restituisce 8.
Restituisce la lunghezza di una stringa, inclusi gli spazi.
LUNGHEZZA("Testo")
Testo è il testo la cui lunghezza deve essere determinata.
=LUNGHEZZA("Buongiorno") restituisce 10.
=LUNGHEZZA(12345,67) restituisce 8.
Converte la stringa specificata nel campo di testo in maiuscolo.
MAIUSC("Testo")
Testo sono le lettere minuscole da convertire in maiuscole.
=MAIUSC("Buon giorno") restituisce BUON GIORNO.
Converte in maiuscolo la prima lettera di tutte le parole di una stringa di testo.
MAIUSC.INIZ("Testo")
Testo è il testo da convertire.
=MAIUSC.INIZ("the document foundation") restituisce The Document Foundation.
Converte tutto il testo in minuscolo.
MINUSC("Testo")
Testo è il testo da convertire.
=MINUSC("Sun") restituisce sun.
Restituisce la posizione di un segmento di testo all'interno di una stringa di caratteri. L'impostazione dell'inizio della ricerca è opzionale. Il testo da ricercare può essere un numero oppure una sequenza di caratteri. La ricerca non distingue tra maiuscole e minuscole. Se il testo non viene trovato, restituisce l'errore 519 (#VALORE).
RICERCA("Testo ricercato"; "Testo" [; Posizione])
TrovaTesto è il testo da cercare.
Testo è il testo da cui parte la ricerca.
Posizione (opzionale) è la posizione nel testo da cui iniziare la ricerca.
=RICERCA(54; 998877665544) restituisce 10.
Sostituisce più volte testi parziali in un testo. Questa funzione permette di sostituire sia lettere che cifre (queste vengono convertite automaticamente in testo). Il risultato della funzione è sempre un testo. Se volete continuare a calcolare con un numero che è stato sostituito, è necessario prima convertirlo nel formato numerico ricorrendo alla funzione VALORE.
Ricordate di inserire qualsiasi testo contenente dei numeri tra virgolette, se non volete che sia interpretato come numero e convertito automaticamente in testo.
RIMPIAZZA("Testo"; Posizione; Numero caratteri; "Nuovo testo")
Testo è il testo nel quale si desidera sostituire una parte.
Posizione è la posizione all'interno del testo da cui partirà la sostituzione.
Numero caratteri è il numero di caratteri da sostituire nel Testo.
Nuovo testo è il testo che sostituirà i caratteri in Testo.
=RIMPIAZZA("1234567";1;1;"444") restituisce "444234567". Un carattere alla posizione 1 viene sostituito dai caratteri specificati come Nuovo testo.
Ripete una stringa di caratteri per il numero di volte specificato.
RIPETI("Testo"; Numero)
Testo è il testo da ripetere.
Numero è il numero delle ripetizioni.
=RIPETI("Buon giorno";2) restituisce Buon giornoBuon giorno.
Refer to the REPT wiki page for more details about this function.
Restituisce il primo o i primi caratteri di un testo.
SINISTRA("Testo" [; Numero caratteri])
Testo è il testo di cui determinare le parole comprese nella parte iniziale.
Numero (opzionale) specifica il numero di caratteri da estrarre da sinistra. Se questo parametro non è definito, viene restituito un solo carattere.
=SINISTRA("disattivare"; 3) restituisce “dis”.
Restituisce i primi caratteri di un testo DBCS.
SINISTRA.B("Testo" [; Numero_byte])
Testo è il testo di cui determinare le parole comprese nella parte iniziale.
Numero_byte (opzionale) specifica il numero di caratteri che SINISTRA.B deve estrarre, basato sui byte. Se questo parametro non è definito, viene restituito un solo carattere.
=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).
=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).
=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).
=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).
=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).
Sostituisce in una stringa un testo esistente con un nuovo testo.
SOSTITUISCI("Testo"; "CercaTesto"; "Nuovo testo" [; Occorrenza])
Testo è il testo in cui i segmenti devono essere scambiati.
CercaTesto è il segmento di testo da sostituire (un determinato numero di volte).
Nuovo testo è il testo che deve sostituire la parola parziale.
Occorrenza (opzionale) indica quale occorrenza della ricerca deve essere sostituita. Se manca questo parametro, il testo ricercato sarà sostituito completamente.
=SOSTITUISCI("123123123"; "3"; "abc") restituisce 12abc12abc12abc.
=SOSTITUISCI("123123123";"3";"abc";2) restituisce 12312abc123.
Restituisce una stringa di un testo. I parametri specificano la posizione iniziale e il numero di caratteri.
STRINGA.ESTRAI("Testo", Inizio; Numero)
Testo è il testo contenente i caratteri da estrarre.
Inizio è la posizione del primo carattere da estrarre dal testo.
Numero specifica il numero dei caratteri nella porzione di testo.
=STRINGA.ESTRAI("office";2;2) restituisce ff.
Restituisce una stringa di un testo DBCS. I parametri specificano la posizione iniziale e il numero di caratteri.
STRINGA.ESTRAI.B("Testo", Inizio; Numero_byte)
Testo è il testo contenente i caratteri da estrarre.
Inizio è la posizione del primo carattere da estrarre dal testo.
Numero_byte specifica il numero di caratteri, in byte, che STRINGA.ESTRAI.B restituirà dal testo.
=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).
=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).
=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).
=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).
=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).
=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).
=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).
=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).
=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).
=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).
=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).
Questa funzione restituisce il testo di destinazione o una stringa di testo vuota se la destinazione non è il testo.
T(Valore)
Se Valore è una stringa di testo o si riferisce a essa, T restituisce quella stringa di testo; in caso contrario restituisce una stringa vuota.
=T(12345) restituisce una stringa vuota.
=T("12345") restituisce la stringa 12345.
Converte un valore in testo in base al formato indicato.
TESTO(Valore; Formato)
Valore è il valore (numerico o di testo) da convertire.
Formato è il testo che definisce il formato. Utilizzate i separatori di decimali e migliaia secondo la lingua impostata nel formato cella.
=TESTO(12,34567;"###,##") restituisce il testo 12,35
=TESTO(12,34567;"000,00") restituisce il testo 012,35
=TESTO("xyz";"=== @ ===") restituisce il testo === xyz ===
Vedere anche Codici dei formati numerici: codici dei formati personalizzati definiti dall'utente.
Converte un numero in testo tailandese, inclusi i nomi di valute tailandesi.
TESTO.BAHT(Numero)
Numero è qualsiasi numero. "Baht" viene aggiunta alla parte integrale del numero e "Satang" viene aggiunta alla parte decimale del numero.
=TESTO.BAHT(12.65) restituisce una stringa in caratteri tailandesi con il significato di "12 Baht e 65 Satang".
Restituisce la posizione di una stringa di testo all'interno di un'altra stringa. Potete anche definire la posizione da cui iniziare la ricerca. Il termine da ricercare può essere un numero o qualsiasi stringa di caratteri. La ricerca distingue tra maiuscole e minuscole.
TROVA("Testo ricercato"; "Testo" [; Posizione])
Testo ricercato è il testo che si desidera trovare.
Testo è il testo da cui parte la ricerca.
Posizione (opzionale) è la posizione nel testo da cui iniziare la ricerca.
=TROVA(76; 998877665544) restituisce 6.
Restituisce il codice numerico del primo carattere Unicode di una stringa di testo.
UNICODE("Testo")
=UNICODE("©") restituisce il numero Unicode 169 per carattere di copyright.
Vedere anche la funzione CARATT.UNI().
Converte un valore numerico in un testo avente il formato valuta. Il valore viene inoltre arrotondato alle cifre decimali indicate. Nel campo di testo Valore va introdotto il numero razionale da convertire nel formato valuta. Volendo, si può anche digitare nel campo Decimali il numero delle cifre decimali da rappresentare nel formato valuta. In mancanza di tale valore vengono usate due cifre decimali.
Il formato della valuta viene definito nelle impostazioni del sistema.
VALUTA(Valore [; Decimali])
Valore può essere un numero, un riferimento a una cella che lo contiene o una formula che lo restituisce.
Decimali è il numero opzionale di posizioni decimali.
=VALUTA(255) restituisce € 255,00 per l'impostazione locale Italiano (Italia) e valuta (EUR);¥255.00 per l'impostazione locale Giapponese (Giappone) e JPY (yes) come valuta o ancora $255.00 per l'impostazione locale Inglese (USA) e la valuta in USD (Dollari).
=VALUTA(367,456;2) restituisce 367,46 €. Utilizza il separatore decimale corrispondente all'area regionale in cui è configurato attualmente il sistema.