Reknearksfunksjonar

Dette avsnittet inneheld ein omtale av reknearksfunksjonar med eksempel.

For Ă„ bruka denne funksjonen 


Set inn → Funksjon → Kategori Rekneark


FEIL.TYPE

Returnerer eit tal som viser feiltypen eller feilverdien #I/T dersom det ikkje er feil.

ADRESSE (ADDRESS pÄ engelsk)

Returnerer ei celleadresse (referanse) som tekst i samsvar med dei oppgjevne rad- og kolonnenummera. Du kan finna ut om adressa er tolka som ei absolutt adresse (for eksempel $A$1), relativ adresse (A1) eller i blanda form (A$1 eller $A1). Du kan ĂČg oppgje namnet pĂ„ reknearket.

Av omsyn til interoperabiliteten har funksjonane ADRESSE og INDIREKTE ein valfri parameter for Ă„ indikere om R1C1-adresse-notasjonen kan brukast i staden for den vanlege A1-notasjonen.

I ADRESSE, vert parameteren sett inn som den fjerde parameteren, som flytter den valfrie arknamn-parameteren til den femte plasseringa.

I INDIREKTE er parameteren lagt til som den andre parameteren.

I begge funksjonane vert R1C1-notasjonen brukt viss argumentet vert sett inn med verdien 0. Viss argumentet ikkje er gjeve eller har ein annan verdi enn 0, sÄ vert A1-notasjonen brukt.

Viss R1C1-notasjonen er brukt, returnerer ADRESSE strengar som brukar utropsteikn (!) som skiljeteikn for arknamnet og INDIREKTE ventar utropsteiknet som skiljeteikn for arknamn. Begge funksjonane brukar framleis punktum (.) som skiljeteikn for arknamn med A1-notasjon.

NÄr du opnar dokument frÄ ODF 1.0/1.1-format der ADRESSE-funksjonen viser eit arknamn som den fjerde parameteren, vert dette endra slik at arknamnet vert den femte parameteren. Det vert sett inn ein ny fjerde parameter med verdien 1.

NÄr du lagrar eit dokument i ODF 1.0/1.1-format, vert den fjerde parameteren i ADRESSE-funksjonen fjerna.

note

Ikkje lagra eit rekneark i det gamle ODF 1.0/11-formatet viss ADRESSE-funksjonen sin nye fjerde parameter inneheld verdien 0.


note

Funksjonen INDIREKTE vert lagra utan konvertering til formatet ODF 1.0/1.1. Viss den andre parameteren er brukt, vil eldre versjonar av Calc returnera ein feil for den funksjonen.


Syntaks

ADRESSE(Rad; Kolonne[; Abs[; A1[; "Ark"]]])

Rad svarar til radnummeret for cellereferansen

Kolonne svarar til kolonnenummeret for cellereferansen (talet, ikkje bokstaven)

Abs bestemmer referansetypen:

1: absolutt ($A$1)

2: radreferansetypen er absolutt; kolonnereferansen er relativ (A$1)

3: rad (relativ); kolonne (absolutt) ($A1)

4: relativ (A1)

A1 (valfri) – viss sett til 0, vert notasjonen R1C1 brukt. Viss parameteren manglar eller er sett til ein annan verdi enn 0, vert notasjonen A1 brukt.

Ark svarar til namnet pÄ arket. Det mÄ vera plassert i dobbelt hermeteikn (" ").

Eksempel:

=ADRESSE(1; 1; 2; "Ark2") returnerer dette: Ark2.A$1

Viss formelen ovanfor er i cella B2 det gjeldande arket og cella A1 i ark 2 inneheld verdien -6, kan du referera indirekte til den refererte cella ved Ă„ skriva inn =ABS(INDIREKTE(B2)). Resultatet er den absolutte verdien av cellereferansen som er vist i B2, som i dette tilfelle er 6.

ARK (SHEET pÄ engelsk)

Returnerer arknummeret til ein referanse eller ein tekst som representerer eit arknamn. Dersom du ikkje skriv inn parametrar, vert resultatet arknummeret til reknearket som inneheld formelen.

Syntaks

ARK([Referanse])

Referanse er valfri og er referansen til ei celle, eit omrÄde eller eit arknamn.

Eksempel

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

DDE

Gjev resultatet av ei DDE-basert lenkje. Dersom innhaldet i det lenkja omrĂ„der vert endra, vert ĂČg resultatet endra. Du mĂ„ lasta reknearket pĂ„ nytt eller velja Rediger → Lenkjer for Ă„ sjĂ„ dei oppdaterte lenkjene. Lenkjer frĂ„ ei plattform til ei anna er ikkje tillate, for eksempel frĂ„ ein installasjon av LibreOfficeDev pĂ„ ein Windows-maskin til eit dokument oppretta pĂ„ ein Linux-maskin.

Syntaks

DDE("Tenar"; "Fil"; "OmrÄde"[; Modus])

Tenar er namnet pÄ eit tenarprogram. Programma for LibreOfficeDev har tenarnamnet «soffice».

Fil er det fullstendige filnamnet medrekna filstien.

OmrÄde er omrÄdet som inneheld data som skal validerast.

Modus er ein valfri parameter som bestemmer kva metode som DDE-tenaren brukar for Ă„ gjera om data til tal.

Eksempel

Forskyving

0 eller manglande

Talformat frÄ cellestilen «Standard»

1

Data vert alltid tolka som standard US engelsk-format.

2

Data vert henta som tekst; inga omgjering til tal.


Eksempel

=DDE("soffice"; "c:\Kontor\dokument\data1.sxc"; "ark1.A1") les celleinnhaldet i celle A1 i ark1 frÄ LibreOfficeDev Calc-reknearket data1.ods.

=DDE("soffice";"c:\Kontor\dokument\motto.sxw";"Dagens Motto") returnerer eit motto i den cella som inneheld denne formelen. FĂžrst mĂ„ du skriva inn ei linje i dokumentet motto.sxw som inneheld mottoteksten og definera ho som den fĂžrste linja av ein bolk med namnet Dagens Motto (i LibreOfficeDev Writer under Set inn → Bolk). Viss mottoet vert endra (og lagra) i LibreOfficeDev Writer-dokumentet, vert mottoet oppdatert i alle LibreOfficeDev Calc cellene der denne DDE-lenkja er definert.

FEILTYPE (ERRORTYPE pÄ engelsk)

Returnerer talet som svarar til ein feilverdi som oppstod i ei anna celle. Ved Ă„ bruka dette talet kan du visa ei feilmelding.

Dersom det oppstÄr ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

note

Statuslinja viser den fÞrehandsdefinerte feilkoden frÄ LibreOfficeDev viss du klikkar pÄ den cella som inneheld feilen.


Syntaks

FEILTYPE(Referanse)

Referanse inneheld adressa til den cella som feilen oppstÄr i.

Eksempel

Viss celle A1 viser Err:518, returnerer funksjonen =FEILTYPE(A1) talet 518.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.ERRORTYPE

FINN.KOLONNE (HLOOKUP pÄ engelsk)

SÞkjer etter ein verdi og ein referanse til cellene nedanfor det merkte omrÄdet. Stadfestar om den fÞrste rada i ei matrise inneheld ein viss verdi. Gjev verdien til ei rad i matrisa avgjort av Indeksen i same kolonne.

SĂžkjinga har stĂžtte for jokerteikn eller regulĂŠre uttrykk. Med regulĂŠre uttrykk slĂ„tt pĂ„, kan du for eksempel skriva inn «all.*» for Ă„ finna den fĂžrste staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal sĂžkja etter ein tekst som ogsĂ„ er eit regulĂŠrt uttrykk, mĂ„ du skriva bakoverstrek (\) framfĂžre kvart teikn eller du mĂ„ lukka inn teksten mellom «\Q» og «\E». Du kan slĂ„ den automatiske evalueringa av jokerteikn og regulĂŠre uttrykk av eller pĂ„ i → LibreOfficeDev Calc → Rekn ut.

warning

NÄr du brukar funksjonar der eitt eller fleire argument er sÞkjekriterium som representerer eit regulÊrt uttrykk, vert det fÞrst prÞvd Ä konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og sÄ vidare. Viss dette gÄr bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. NÄr du brukar eit sprÄk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulÊre uttrykk fungera. For Ä tvinga evalueringa av det regulÊre uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Syntaks

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Du kan finna ei forklaring pÄ parameterane i FINN.RAD kolonnar og rader har bytt plass)

Handsaming av tomme celler

Eksempel

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

A

B

C

D

...

DO

1

Element

Hydrogen

Helium

Lithium

...

Oganesson

2

Symbol

H

He

Li

...

Og

3

Atomic Number

1

2

3

...

118

4

Relative Atomic Mass

1.008

4.0026

6.94

...

294


=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

FINN.RAD (VLOOKUP pÄ engelsk)

Loddrett sÞking med tilvising til tilstÞytane celler til hÞgre. Denne funksjonen kontrollerer om ein bestemt verdi finst i den fÞrste kolonnen i ei matrise. Funksjonen returnerer sÄ verdien i den same rada i kolonnen som er namngjeven i Indeks. Viss parameteren Sortert manglar eller er sett til SANN, vert dataa sorterte i stigande rekkjefÞlgje. Viss det eksakte oppslag ikkje vart funne, vert den siste verdien som er mindre enn kriteriet returnert. Viss Sortert er sett til USANN eller null, mÄ der vera eit eksakt samanfall, elles vert feilen Feil: Verdi ikkje tilgjengeleg returnert. Med ein verdi pÄ null treng dataa ikkje vera sorterte stigande.

SĂžkjinga har stĂžtte for jokerteikn eller regulĂŠre uttrykk. Med regulĂŠre uttrykk slĂ„tt pĂ„, kan du for eksempel skriva inn «all.*» for Ă„ finna den fĂžrste staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal sĂžkja etter ein tekst som ogsĂ„ er eit regulĂŠrt uttrykk, mĂ„ du skriva bakoverstrek (\) framfĂžre kvart teikn eller du mĂ„ lukka inn teksten mellom «\Q» og «\E». Du kan slĂ„ den automatiske evalueringa av jokerteikn og regulĂŠre uttrykk av eller pĂ„ i → LibreOfficeDev Calc → Rekn ut.

warning

NÄr du brukar funksjonar der eitt eller fleire argument er sÞkjekriterium som representerer eit regulÊrt uttrykk, vert det fÞrst prÞvd Ä konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og sÄ vidare. Viss dette gÄr bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. NÄr du brukar eit sprÄk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulÊre uttrykk fungera. For Ä tvinga evalueringa av det regulÊre uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Syntaks

=FINN.RAD(Oppslag; Matrise; Indeks[; SortertOmrÄdeOppslag])

Oppslag er verdien av kva type som helst som det vert sett etter i den fĂžrste kolonnen i matrisa.

Matrise er referansen som skal innehalda minst sÄ mange kolonnar som det er fÞrt opp i Indeks-argumentet.

Indeks er kolonnenummeret i omrÄdet som inneheld verdien som skal returnerast. Den fÞrste kolonnen har talet 1.

SortertOmrÄde er ein valfri parameter som indikerer om den fÞrste kolonnen i matrisa inneheld omrÄdegrenser i staden for vanlege verdiar. I denne modusen returnerer uttrykket verdien i rada med den fÞrste kolonnen som har ein verdi som er lik eller mindre enn oppslag. Den kan for eksempel innehalde datoar nÄr nokre MVA-verdiar er endra nÄr verdiane representerer startdatoar for ein periode nÄr ein bestemt MVA-verdi var brukt. Eit sÞk etter ein dato som manglar i den fÞrste matrisekolonnen, men er mellom nokre eksisterande grensedatoar, vil returnera den lÄgaste av dei slik at det er rÄd Ä finna dataa som hÞver til den sÞkte datoen. Bruk USANN eller null viss den fÞrste kolonnen ikkje inneheld omrÄdegrenser. NÄr denne parameteren er sann eller ikkje gjeven, mÄ den fÞrste kolonnen i matrisen vera sortert i stigande rekkjefÞlgje. Ei sÞk i sorterte kolonnar gÄr mykje raskare og funksjonen returnerer alltid ein verdi, sjÞlv om sÞkjeverdien ikkje samsvarar nÞyaktig, viss han er stÞrre enn den lÄgaste verdien i den sorterte lista. I usorterte lister mÄ sÞkjeverdien samsvara nÞyaktig elles vil funksjonen returnera #I/T med meldinga Feil: verdi ikkje tilgjengeleg .

Handsaming av tomme celler

Eksempel

Du Þnskjer Ä skriva inn nummeret pÄ ein rett i cella A1 og at namnet pÄ den valde retten skal visast i nabocella B1 med ein gong. Verdien til konverteringa frÄ nummer til namn finst i omrÄdet D1:E100. D1 inneheld 100, E1 inneheld namnet GrÞnnsakssuppe og sÄ vidare opp til 100 menyoppfÞringar Tala i kolonne D er sorterte i stigande rekkjefÞlgje, difor er den valfrie parameteren Sortert ikkje nÞdvendig.

Skriv inn denne formelen i B1:

=FINN.RAD(A1; D1:E100; 2)

SÄ snart du skriv inn eit tal i A1 vil B1 visa den teksten som ligg i den andre kolonnen i referansen D1:E100. Skriv du inn eit tal som ikkje finst, vil teksten tilsvarande det neste talet i rada verta vist. Dette kan du forhindra ved Ä skriva inn USANN som den siste parameteren i formelen. Det vil dÄ verta vist ei feilmelding om ikkje-eksisterande tal vert skrivne inn.

FORSKYVING (OFFSET pÄ engelsk)

Returnerer verdien av ei celle som ligg eit visst tal pÄ rader og kolonnar frÄ eit gjeve referansepunkt.

Denne funksjonen vert alltid rekna ut pÄ nytt nÄr rekna ut pÄ nytt vert utfÞrt.

Syntaks

FORSKYVING(Referanse; Rader; Kolonnar[; HĂžgd[; Breidd]])

Referanse er cella som funksjonen leitar etter den nye referansen frÄ.

Rader er talet pÄ rader som referansen vart korrigert oppover (negativ verdi) eller nedover med. Bruk 0 for Ä verta verande i den same rada.

Kolonnar er talet pÄ kolonnar som referansen vart korrigert til venstre (negativ verdi) eller til hÞgre. Bruk 0 for Ä bli i den same kolonnen.

HÞgd (valfri) er den loddrette hÞgda pÄ eit omrÄde som byrjar ved den nye referanseposisjonen.

Breidd (valfri) er den vassrette breidda pÄ eit omrÄde som byrjar ved den nye referanseposisjonen.

Argumenta HĂžgd og Breidd kan ikkje resultera i null eller negativ startrad eller startkolonne.

Argumenta HÞgd og Breidd kan ikkje resultera i null eller negativt tal pÄ rader eller kolonnar.

I funksjonane i LibreOfficeDev Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein pÄfÞlgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

Eksempel

=FORSKYVING(A1; 2; 2) returnerer verdien i celle C3 (A1 flytt to rader og to kolonnar nedover). Viss C3 inneheld verdien 100 returnerer denne funksjonen verdien 100.

=FORSKYVING(B2:C3;1;1) returnerer ein referanse til B2:C3 flytt 1 rad ned og 1 kolonne til hĂžgre (C3:D4).

=FORSKYVING(B2:C3;-1;-1) returnerer ein referanse til B2:C3 flytt 1 rad opp og ein kolonne til venstre (A1:B2).

=FORSKYVING(B2:C3;0;0;3;4) returnerer ein referanse til B2:C3 med storleiken endra til 3 rader og 4 kolonnar (B2:E4).

=FORSKYVING(B2:C3;1;0;3;4) returnerer ein referanse til B2:C3 flytt ei rad ned og med storleiken endra til 3 rader og 4 kolonnar (B3:E5).

=SUMMER(FORSKYVING(A1;2;2;5;6)) bestemmer summen av omrÄdet som startar i celle C3 og har ei hÞgd pÄ 5 rader og ei breidd pÄ 6 kolonnar (omrÄde=C3:H7).

note

Dersom Breidd eller HÞgd er oppgjeve, returnerer FORSKYVING-funksjonen referanse til eit celleomrÄde. Dersom Referanse er ein referanse til ei enkel celle og bÄde Breidd og HÞgd ikkje er oppgjeve, vert det returnert ein referanse til éi celle.


HENTPIVOTDATA (GETPIVOTDATA pÄ engelsk)

Funksjonen HENTPIVOTDATA returnerer ein resultatverdi frÄ ein pivottabell. Verdien vert adressert ved hjelp av felt- og elementnamna slik at adresseringa framleis er gyldige sjÞlv om oppbyggjinga av pivottabellen vert endra.

Syntaks

To ulike syntaksdefinisjonar kan brukast:

HENTPIVOTDATA(MÄlfelt; pivottabell[; Felt 1; Element 1][; ... [Felt 126; Element 126]])

eller

HENTPIVOTDATA(pivottabell;vilkÄr)

Den andre syntaksen vert brukt viss nÞyaktig to parameter er gjevne, der den fÞrste parameteren er ein referanse til ei celle eller eit celleomrÄde. I alle andre tilfelle vert den fÞrste syntaksen brukt. Funksjonsvegvisaren viser det fÞrste syntaksen.

FĂžrste syntaks

MĂ„lfelt er ein tekststreng som vel eit av datafelta i pivottabellen. Tekststrengen kan vera namnet pĂ„ kjeldekolonnen eller namn pĂ„ datafeltet som vert vist i tabellen ("Summer → Sal").

pivottabell er ein referanse til ei celle eller eit celleomrÄde som er plassert inne i ein pivottabell eller som indeheld ein pivottabell. Viss celleomrÄdet inneheld fleire pivottabellar, vert den sist brukte pivottabellen brukt.

Viss det ikkje er oppgjeve noko Felt n / Element n par, vert totalen returnert. Elles utgjer kvart par vilkÄr som mÄ oppfyllast. Felt n er namnet pÄ eit felt frÄ pivottabellen. Element n er namnet pÄ eit element frÄ dette feltet.

Viss pivottabellen inneheld ein einaste resultatverdi som oppfyller alle vilkÄra, eller eit resultat for delsummar som summerer alle passande verdiar, vert det resultatet returnert. Viss det ikkje finst passande verdiar eller det finst fleire utan delsum, vert det returnert ei feilmelding. Desse vilkÄra gjeld for resultat som er tekne med i pivottabellen.

Viss kjeldedata inneheld element som er gÞymde som fÞlgje av innstillingane for pivottabellen, vert desse ignorerte. RekkjefÞlgja pÄ felt og element er ikkje viktig. Namn pÄ felt og element skil ikkje mellom store og smÄ bokstavar.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Verdiar frÄ delsummar frÄ pivottabellen vert berre brukte viss funksjonen «auto» er brukt. (Bortsett frÄ nÄr dei vert nytta i vilkÄret, sjÄ andre syntaks nedanfor).

Andre syntaks

pivottabell har den same meininga som ved fĂžrste syntaks.

Avgrensingar er ei mellomromsseparert liste. Heile strengen mÄ vera innskriven mellom doble hermeteikn (" ") viss du ikkje refererer til tekststrengen frÄ ei anna celle. Kvart element kan vera mellom enkle hermeteikn (' ').

Ei av innskrivingane kan vera namnet pÄ datafeltet. Namnet pÄ datafeltet kan slÞyfast berre viss pivottabellen inneheld berre eitt datafelt.

Kvar av dei andre innskrivingane spesifiserer eit vilkÄr pÄ forma Felt[Element] (med teiknmaska [ og ]), eller berre Element viss elementnamnet er brukt berre ein gong i alle felta som er brukte i pivottabellen.

Eit funksjonsnamn kan leggjast til pÄ forma Felt[element;funksjon], som gjer at kriteria berre passar pÄ delsumverdiar som nyttar denne funksjonen. Moglege funksjonsnamn er Summer, Tall, Middel, Maks, Min, Produkt, Tal (berre tal), Stdav (utval), Stdavp (populasjon), Varians (utval) og Variansp (populasjon). Systemet skil ikkje mellom smÄ og store bokstavar.

HYPERLENKJE (HYPERLINK pÄ engelsk)

NÄr du trykkjer pÄ ei celle som inneheld HYPERLENKJE-funksjonen, vert hyperlenkja opna.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

tip

For Ä opna ei hyperlenkja celle med tastaturet, marker cella, trykk «F2» for Ä gÄ i redigeringsmodus, flytt peikaren framfÞre hyperlenkja, trykk «Shift+F10» og vel sÄ Opna hyperlenkje.


Syntaks

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

Talet 0 vert returnert for tomme celler og matriselement.

Eksempel

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

INDEKS (INDEX pÄ engelsk)

INDEKS gjev innhaldet av ei celle som anten er spesifisert med rad og kolonne eller som eit namngjeve omrÄde. Avhengig av samanhengen, gjev INDEKS anten innhald eller ein referanse.

Syntaks

INDEKS(Referanse[; Rad[; Kolonne[; OmrÄde]]])

Referanse er ein cellereferanse som anten er skrive inn direkte eller ved Ä bruka namnet pÄ eit omrÄde. Viss referansen inneheld fleire omrÄde, mÄ du skriva referansen eller omrÄdenamnet i parentes.

Rad (valfri) representerer radnummeret til referanseomrÄdet som skal returnerast som ein verdi. Viss denne er null (ingen spesifikk rad), vert alle refererte rader returnerte.

Kolonne (valfri) representerer kolonnenummeret til referanseomrÄdet som skal returnerast som ein verdi. Viss denne er sett til null (ingen spesifikk kolonne), vert alle dei refererte kolonnane returnerte.

OmrÄde (valfri) svarar til indeksen for underomrÄdet som refererer til fleire omrÄde.

Eksempel

=INDEKS(Prisar;4;1) returnerer verdien frĂ„ rad 4 og kolonne 1 av databaseomrĂ„det definert i Data → Definer omrĂ„de som Prisar.

=INDEKS(SumX; 4; 1) returnerer verdien frĂ„ omrĂ„det SumX i rad 4 og kolonne 1 som definert i Set inn → Namn → Skriv inn.

=INDEKS(A1:B6;1) returnerer ein referanse til den fĂžrste rada i A1:B6.

=INDEKS(A1:B6;0;1) returnerer ein referanse til den fĂžrste kolonnen i A1:B6.

=INDEKS((multi);4;1) indikerer verdien i rad 4 kolonne 1 i det (multi-)omrĂ„det som du gav namn under Set inn → Namn → Skriv inn som multi. MultiomrĂ„det kan innehalda fleire enkelte rektangulĂŠre omrĂ„de, alle med ei rad 4 og kolonne 1. Viss du seinare Ăžnskjer Ă„ kalla opp den andre blokka i multiomrĂ„det, kan du skriva inn talet 2 som omrĂ„de-parameter.

=INDEKS(A1:B6;1;1) returnerer verdien Þvst i det venstre hjÞrnet av omrÄdet A1:B6.

=INDEKS((multi);0;0;2) returnerer ein referanse til det andre omrÄdet av multiomrÄdet.

INDIREKTE (INDIRECT pÄ engelsk)

Returnerer referansen som er oppgjeve ved ein tekststreng. Du kan ĂČg bruka denne funksjonen til Ă„ finna omrĂ„de til ein samsvarande streng.

Denne funksjonen vert alltid rekna ut pÄ nytt nÄr rekna ut pÄ nytt vert utfÞrt.

Av omsyn til interoperabiliteten har funksjonane ADRESSE og INDIREKTE ein valfri parameter for Ă„ indikere om R1C1-adresse-notasjonen kan brukast i staden for den vanlege A1-notasjonen.

I ADRESSE, vert parameteren sett inn som den fjerde parameteren, som flytter den valfrie arknamn-parameteren til den femte plasseringa.

I INDIREKTE er parameteren lagt til som den andre parameteren.

I begge funksjonane vert R1C1-notasjonen brukt viss argumentet vert sett inn med verdien 0. Viss argumentet ikkje er gjeve eller har ein annan verdi enn 0, sÄ vert A1-notasjonen brukt.

Viss R1C1-notasjonen er brukt, returnerer ADRESSE strengar som brukar utropsteikn (!) som skiljeteikn for arknamnet og INDIREKTE ventar utropsteiknet som skiljeteikn for arknamn. Begge funksjonane brukar framleis punktum (.) som skiljeteikn for arknamn med A1-notasjon.

NÄr du opnar dokument frÄ ODF 1.0/1.1-format der ADRESSE-funksjonen viser eit arknamn som den fjerde parameteren, vert dette endra slik at arknamnet vert den femte parameteren. Det vert sett inn ein ny fjerde parameter med verdien 1.

NÄr du lagrar eit dokument i ODF 1.0/1.1-format, vert den fjerde parameteren i ADRESSE-funksjonen fjerna.

note

Ikkje lagra eit rekneark i det gamle ODF 1.0/11-formatet viss ADRESSE-funksjonen sin nye fjerde parameter inneheld verdien 0.


note

Funksjonen INDIREKTE vert lagra utan konvertering til formatet ODF 1.0/1.1. Viss den andre parameteren er brukt, vil eldre versjonar av Calc returnera ein feil for den funksjonen.


Syntaks

INDIREKTE(Referanse[; A1])

Referanse tilsvarer ein referanse til ei celle eller eit omrÄde (i tekstform) som verdien skal returnerast frÄ.

A1 (valfri) – viss sett til 0, vert notasjonen R1C1 brukt. Viss parameteren manglar eller er sett til ein annan verdi enn 0, vert notasjonen A1 brukt.

note

Viss du opnar eit Excel regneark som brukar indirekte adresser utrekna frÄ strengfunksjonar, vert arkadressene ikkje konverterte automatisk. For eksempel vert Exceladressa i INDIREKTE("filnamn!arknamn"&B1) ikkje konvertert til Calc-adressa INDIREKTE("filnamn!arknamn"&B1)


Eksempel

=INDIREKTE(A1) er lik 100 viss A1 inneheld C108 som ein referanse og celle C108 inneheld verdien 100.

=SUMMER(INDIREKTE("A1:" & ADRESSE(1;3))) summerer cellene i omrÄdet frÄ A1 til den cella som er definert ved rad 1 og kolonne 3. Det vil seia at A1:C1 er oppsummert.

KOLONNAR (COLUMNS pÄ engelsk)

Returnerer talet pÄ kolonnar i den oppgjevne referansen.

Syntaks

KOLONNAR(Matrise)

Matrise er referansen til eit celleomrÄde der det totale talet pÄ kolonnar finst. Argumentet kan ogsÄ vera ei enkelt celle.

Eksempel

=KOLONNAR(B5) returnerer 1 fordi ei celle inneheld berre ein enkelt kolonne.

=KOLONNER(A1:C5) er lik 3. Referansen omfattar tre kolonnar.

=KOLONNAR(Kanin) Returnerer 2 viss Kanin er det namngjevne omrÄdet (C1:D3).

KOLONNE (COLUMN pÄ engelsk)

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

Syntaks

KOLONNE([Referanse])

Referanse er referansen til ei celle eller eit celleomrÄde som det fÞrste kolonnenummeret skal finnast i.

Viss det ikkje vert skrive inn referanse, vert kolonnenummeret for cella som formelen er skrive inn i funne.LibreOfficeDev Calc set automatisk referansen til den gjeldande cella.

Eksempel

=KOLONNE(A1) er lik 1. Kolonne A er den fĂžrste kolonnen i tabellen.

=KOLONNE(C3:E3) er lik 3. Kolonne C er den tredje kolonnen i tabellen.

=KOLONNE(D3:G10) returnerer 4, fordi kolonne D er den fjerde kolonnen i tabellen, og KOLONNE-funksjonen ikkje er brukt som ein matriseformel. (I dette tilfellet vil den fĂžrste verdien i matrisa alltid verta brukt som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) returnerer begge 2 fordi referansen berre inneheld kolonne B som den andre kolonnen i tabellen. Fordi enkelt-kolonneomrÄde berre har eitt kolonnenummer, gjer det ingen skilnad om formelen vert brukt som ein matriseformel eller ei.

==KOLONNE() returnerer 3 viss formelen vart skriven i kolonne C.

{=KOLONNE(Kanin)} returnerer enkeltradmatrisen (3; 4) viss «Kanin» er det namngjevne omrÄdet (C1:D3).

OMRÅDE (AREAS pĂ„ engelsk)

Returnerer talet pÄ individuelle omrÄde som er med i eit samansett omrÄde. Eit dataomrÄde kan vera bÄde ei enkeltcelle og eit samanhengande celleomrÄde.

Funksjonen krev eitt enkelt argument. Viss du skriv inn fleire omrÄde, mÄ du setja dei i eigne parentesar. Du kan skrive inn fleire omrÄde ved Ä skilja dei med semikolon (;), men desse vert automatisk omgjort til tilde (~). Tilde vert brukt for Ä slÄ saman omrÄde.

Syntaks

OMRÅDE(Referanse)

Referanse representerer referansen til ei celle eller eit celleomrÄde.

Eksempel

=OMRÅDE(A1:B3;F2;G1) returnerer 3, fordi det er ein referanse til tre celler og/eller celleomrĂ„de. Etter innskrivinga vert det konvertert til = OMRÅDE((A1:B3~F2~G1)).

=OMRÅDE(Alt) returnerer 1, viss du har definert eit omrĂ„de med namnet Alt under Data → Definer omrĂ„de.

RAD

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

Syntaks

RAD(Referanse)

Referanse er ei celle, eit omrÄde eller namnet pÄ eit omrÄde.

Viss du ikkje gjev ein referanse, vert radnummeret for cella som formelen er skrive inn i brukt.LibreOfficeDev Calc set automatisk referansen til den gjeldande cella.

Eksempel

RAD(B3) returnerer 3 fordi referansen viser til den tredje rada i tabellen.

{=RAD(D5:D8)} returnerer matrisa med enkeltkolonnen (5, 6, 7, 8) fordi den gjevne referansen inneheld radene 5 til 8.

=RAD(D5:D8) returnerer 5 fordi RAD-funksjonen ikkje er brukt som matriseformel og berre nummeret pÄ den fÞrste rada i referansen vert returnert.

{=RAD(A1:E1)} og =RAD(A1:E1) returnerer begge 1 fordi referansen indeheld berre rad 1 som den fÞrste rada i tabellen. (Fordi omrÄde med enkeltrader berre har eitt radnummer, gjer det ingen skilnad om formelen er brukt som matriseformel eller ei).

=RAD() returnerer 3 viss formelen vart skriven inn i rad 3.

{=RAD(Kanin)} returnerer matrisa med enkeltkolonnen (1, 2, 3) viss «Kanin» er det namngjevne omrÄdet (C1:D3).

RADER (ROWS pÄ engelsk)

Returnerer talet pÄ rader i ein referanse eller tabell.

Syntaks

RADER(Matrise)

Matrise er referansen eller det namngjevne omrÄdet som det totale talet pÄ rader skal fastsetjast for.

Eksempel

=Rader(B5) returnerer 1, fordi ei celle inneheld berre éi rad.

=RADER(A10;B12) returnerer 3.

=RADER(Kanin) returnerer 3, viss «Kanin» er det namngjevne omrÄdet (C1:D3).

SAMANLIKNA (MATCH pÄ engelsk)

Returnerer den relative posisjonen til eit element i ein tabell, der elementet svarar til ein viss verdi. Gjev posisjonen til verdien funnen i sĂžkjetabellen som eit tal.

Syntaks

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

SĂžkjetabell er referansen som det skal sĂžkjast i. Ein sĂžkjetabell kan vera ei einskild rad eller ein einskild kolonne eller ein del av desse.

Type kan ha verdiane 1, 0 eller -1. Visss Type = 1 eller viss denne valfrie parameteren manglar, gÄr ein ut frÄ at den fÞrste kolonnen i sÞkjeomrÄdet er sortert i stigande rekkjefÞlgje. Med Type = -1 gÄr ein ut frÄ at kolonnen er sortert i fallande rekkjefÞlgje. Dette svarar til slik det vert gjort i Microsoft Excel.

Viss Type = 0, vil berre identiske resultat verta funne. Viss sÞkekriteriet finst fleire stadar, vil berre det fÞrste funnet verta returnert. Det er berre med Type = 0 at du kan leita etter regulÊre uttrykk (dersom slÄtt pÄ i innstillingane for utrekning) eller jokerteikn (dersom slÄtt pÄ i innstillingane for utrekning).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

SĂžkjinga har stĂžtte for jokerteikn eller regulĂŠre uttrykk. Med regulĂŠre uttrykk slĂ„tt pĂ„, kan du for eksempel skriva inn «all.*» for Ă„ finna den fĂžrste staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal sĂžkja etter ein tekst som ogsĂ„ er eit regulĂŠrt uttrykk, mĂ„ du skriva bakoverstrek (\) framfĂžre kvart teikn eller du mĂ„ lukka inn teksten mellom «\Q» og «\E». Du kan slĂ„ den automatiske evalueringa av jokerteikn og regulĂŠre uttrykk av eller pĂ„ i → LibreOfficeDev Calc → Rekn ut.

warning

NÄr du brukar funksjonar der eitt eller fleire argument er sÞkjekriterium som representerer eit regulÊrt uttrykk, vert det fÞrst prÞvd Ä konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og sÄ vidare. Viss dette gÄr bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. NÄr du brukar eit sprÄk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulÊre uttrykk fungera. For Ä tvinga evalueringa av det regulÊre uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Eksempel

=SAMANLIKNA(200;D1:D100) sÞkjer i omrÄdet D1:D100, som er sortert etter kolonne D, etter verdien 200. SÄ snart denne verdien er nÄdd, vert radnummeret der verdien vart funne returnert. Viss ein hÞgare verdi vart funnen i sÞket i kolonnen, vert radnummeret for den fÞrre rada returnert.

SLÅ.OPP (LOOKUP pĂ„ engelsk)

Returnerer innhaldet av ei celle anten frĂ„ eit omrĂ„de med ei rad eller ein kolonne. Du kan ogsĂ„ returnera den tildelte verdien, med den same indeksen, i ein annan kolonne eller ei anna rad. I motsetnad til FINN.RAD og FINN.KOLONNE kan sĂžkje- og resultatvektoren vera pĂ„ ulike stadar. Dei treng ikkje grensa opp mot kvarandre. SĂžkjevektoren for SLÅ.OPP mĂ„ vera sortert i stigande rekkjefĂžlgje, ellers vil sĂžket ikkje returnera eit brukbart resultat.

note

Viss SLÅ.OPP ikkje kan finna sþkjekriteriet, vert den stþrste verdien i sþkjevektoren som er mindre enn eller lik sþkjekriteriet bruk.


SĂžkjinga har stĂžtte for jokerteikn eller regulĂŠre uttrykk. Med regulĂŠre uttrykk slĂ„tt pĂ„, kan du for eksempel skriva inn «all.*» for Ă„ finna den fĂžrste staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal sĂžkja etter ein tekst som ogsĂ„ er eit regulĂŠrt uttrykk, mĂ„ du skriva bakoverstrek (\) framfĂžre kvart teikn eller du mĂ„ lukka inn teksten mellom «\Q» og «\E». Du kan slĂ„ den automatiske evalueringa av jokerteikn og regulĂŠre uttrykk av eller pĂ„ i → LibreOfficeDev Calc → Rekn ut.

warning

NÄr du brukar funksjonar der eitt eller fleire argument er sÞkjekriterium som representerer eit regulÊrt uttrykk, vert det fÞrst prÞvd Ä konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og sÄ vidare. Viss dette gÄr bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. NÄr du brukar eit sprÄk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulÊre uttrykk fungera. For Ä tvinga evalueringa av det regulÊre uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Syntaks

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

SÞkjevektor er eit omrÄde med 1 rad eller 1 kolonne som det skal sÞkjast i.

Resultatvektor er eit anna omrÄde med 1 rad eller 1 kolonne som resultatet vert henta frÄ. Resultatet er resultatvektorcella som har same indeks som funnet i sÞkjevektoren har.

Handsaming av tomme celler

Eksempel

=SLÅ.OPP(A1; D1:D100; F1:F100) sĂžkjer den tilsvarande cella i omrĂ„det D1:D100 for talet du skreiv inn i A1. Indeksen vert bestemt av fĂžrekomsten der, for eksempel den 12. cella i dette omrĂ„det. Innhaldet i den 12. cella vert dĂ„ returnert som verdien av funksjonen (i resultatvektoren).

STIL (STYLE pÄ engelsk)

Legg til ein stil til den cella som inneheld formelen. Etter eit bestemt tidsrom kan ein annan stil verta lagt til. Funksjonen returnerer alltid verdien 0 slik at du kan leggja han til ein annan funksjon utan Ä endra verdien i denne. Brukt saman med funksjonen GJELDANDE kan du ogsÄ leggja til ein farge i ei celle avhengig av celleverdien. For eksempel vil =...+STIL(VISS(GJELDANDE()>3;"raud";"grÞn")) leggja stilen «raud» til cella viss verdien er over 3, elles vert stilen «grÞn» brukt. Begge celleformata mÄ vera definerte pÄ fÞrehand.

Syntaks

STIL("Stil"[; Tid[; "Stil2"]])

Stil er namnet pÄ ein cellestil tildelt cella. Stilnamn mÄ skrivast i hermeteikn (" ").

Tid er ein valfri tidsperiode i sekund. Viss denne parameteren manglar, vil stilen ikkje verta endra etter eit bestemt tidsrom.

Stil2 er den valfrie cellestilen tildelt cella etter eit bestemt tidsrom. Viss denne parameteren manglar, vert stilen «Standard» brukt.

I funksjonane i LibreOfficeDev Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein pÄfÞlgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

Eksempel

=STIL("Usynleg";60;"Standard") formaterer cella i gjennomsiktig format i 60 sekund etter at dokumentet vart rekna ut pÄ nytt eller lese inn, deretter vert standardformat brukt. Begge celleformata mÄ vera definerte pÄ fÞrehand.

Sidan STIL() har returverdien null, vert denne verdien lagt til ein streng. Dette kan du unngÄ ved Ä nytta T() som vist i eksempelet nedanfor.

="Tekst"&T(STIL"minStil"))

SjÄ ogsÄ ein anna eksempel under GJELDANDE().

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.STYLE

TAL.PÅ.ARK (SHEETS pĂ„ engelsk)

Finn arkmengda i ein referanse. Om du ikkje oppgjev nokon parametrar, gjev han arkmengda i dette dokumentet.

Syntaks

TAL.PÅ.ARK([Referanse])

Referanse er referansen til eit ark eller eit omrÄde. Denne parameteren er valfri.

Eksempel

=TAL.PÅ.ARK(Ark1.A1:Ark3.G12) returnerer 3 viss Ark1, Ark2 og Ark3 finst i den oppgjevne rekkjefþlgja.

VEL (CHOOSE pÄ engelsk)

Brukar eit register for Ä returnera ein verdi frÄ ei liste med opp til 30 verdiar.

Syntaks

VEL(Indeks; Verdi1 [; Verdi2 [; 
 [; Verdi30]]])

Indeks er eIn referanse eller eIt tal mellom 1 og 30, som viser kva verdiar som skal takast frÄ lista.

Verdi1, Verdi2 
 Verdi30 er lista med verdiar skrivne inn som ein referanse til ei celle eller som individuelle verdiar.

Eksempel

=VEL(A1; B1; B2; B3; "I dag"; "I gÄr"; "I morgon") vil for eksempel returnera innhaldet av celle B2 for A1 = 2; for A1 = 4 vil funksjonen returnera teksten "I dag".